Add folder name to beginning of filename

Question

I have a directory structure as below:

Folder
  > SubFolder1
    > FileName1.abc
    > Filename2.abc
    > .............

  > SubFolder2
    > FileName11.abc
    > Filename12.abc
    > ..............

  > ..........

etc. I want to rename the files inside the subfolders as:

SubFolder1_Filename1.abc
SubFolder1_Filename2.abc
SubFolder2_Filename11.abc
SubFolder2_Filename12.abc

i.e. add the folder name at the beginning of the file name with the delimiter "_". The directory structure should remain unchanged. Note: Beginning of file name is same. e.g. in above case File*.

I made below Script

---

for /r "PATH" %%G in (.) do (
  pushd %%G
  for %%* in (.) do  set MyDir=%%~n* 
  FOR %%v IN (File*.*) DO REN %%v  "%MyDir%_%%v" 
  popd
  ) 

---

Problem with the above script is that it is taking only one Subfolder name and placing it to the beginning of file name irrespective of the folder.

Answer 1

You can do this in a more user friendly way using ReNamer, with a single renaming rule:

1. Insert ":File_FolderName:_" as Prefix (skip extension)

You can also save it as a Preset and use it for command line renaming.

Answer 2

To rename only files in the immediate child folders

@echo off
pushd "Folder"
for /d %%D in (*) do (
  for %%F in ("%%~D\*") do (
    for %%P in ("%%F\..") do (
      ren "%%F" "%%~nxP_%%~nxF"
    )
  )
)
popd

To recursively rename all files in child folders

@echo off
pushd "Folder"
for /d %%D in (*) do (
  pushd "%%D"
  for /r %%F in (*) do (
    for %%P in ("%%F\..") do (
      ren "%%F" "%%~nxP_%%~nxF"
    )
  )
  popd
)
popd

Make sure you only run either script once! You don't want to put multiple prefixes in front of the files :-)

Additional code could be added to make it safe to run multiple times.

Answer 3

You could do it easily by using Windows Powershell. That's a two-line script to rename all files in subfolders the way the file name gets a subfolder name prefix. Consider this simple structure in Drive D:

D:\folder1\Sub1

         Sub1 - AAAA.txt
          Sub1 - BBBB.txt
           Sub1 - CCC.txt

D:\folder1\Sub2

          0 AAAAA.txt
          0 CCCC.txt

Here is the script:

PS C:\Users\User> cd D:\folder1

PS D:\folder1> get-childitem -recurse | Rename-Item -NewName {$.Directory.Name + " - " + $.Name}

By running the script all files will be renamed with directory name prefix.

Answer 4

If you want to rename files inside subfolder only this is the solution.

for %%f in (.) do set "A=%%~dpnxf\"
for /r "%A%" %%f in (.) do call :func "%%~f"
goto :EOF
:func
set "B=%~1"
for %%g in ("%B%") do set "C=%%~dpnxg"
for %%g in ("%C%") do set "D=%%~nxg"
cd  %C%
set "k=%C%\"
if NOT %A%==%k% FOR %%v IN (*.*) DO REN "%%v" "%D%_%%v" 
goto :EOF

Answer 5

I use Bulk Rename Utility (TGRMN Software) which has a lot of options for renaming ; including appending folder name to file name as a prefix or a sufix , including choosing what separator you want between them, and down to what level of subfolder you want to append

Bulk Rename Utility