1

Having tried and failed to modify the XSL from here: Distinct elements and grouping

I'm posting here to ask if anyone could please help. I've basically got the same data structure (mine is actually an RSS feed of products) as in the above post, but I want to list the Description elements uniquely, in sorted order where the File element contains a particular value.

I believe the XPath for the File select would be:

*/File[text()='file1']

for example, to take only the File elements containing the text "file1".

I am unable to work out how to get: "all distinct Description elements sorted, which have a File sibling with value 'file1'".

Any and all help will be very, very much appreciated!

Thanks,

Matt.

Community
  • 1
  • 1
Matt W
  • 11,753
  • 25
  • 118
  • 215
  • Actually, it's quite good that you have linked to a similar question. This way I can give you a complete solution and you still have some thinking left to do, adapting it to your actual situation. ;-) – Tomalak Oct 23 '09 at 16:03

1 Answers1

1

XSLT 1.0:

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>

  <!-- index Description elements by their text value -->
  <xsl:key name="kDescription" match="Description" use="text()" />

  <xsl:template match="/">
    <output>
      <!-- process all Description elements... -->
      <xsl:apply-templates select="Problems/Problem/Description">
        <!-- ...sorted by their own text value, ascending -->
        <xsl:sort select="text()" />
        <!-- pass in the File value that we want to filter for -->
        <xsl:with-param name="file" select="'file1'" />
      </xsl:apply-templates>
    </output>
  </xsl:template>

  <xsl:template match="Description">
    <xsl:param name="file" select="''" />
    <!-- 
      check if the current Description node is the first in its
      respective group, that has a File value we care for
    -->
    <xsl:if test="
      $file != ''
      and
      generate-id()
      =
      generate-id(key('kDescription', .)[../File = $file][1])
    ">
      <!-- for the sake of simplicity, just make a copy here -->
      <xsl:copy-of select="." />
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

With this input:

<Problems>
  <Problem>
    <File>file1</File>
    <Description>desc1</Description>
  </Problem>
  <Problem>
    <File>file1</File>
    <Description>desc2</Description>
  </Problem>
  <Problem>
    <File>file2</File>
    <Description>desc3</Description>
  </Problem>
  <Problem>
    <File>file2</File>
    <Description>desc1</Description>
  </Problem>
  <Problem>
    <File>file1</File>
    <Description>desc2</Description>
  </Problem>
</Problems>

I get:

<output>
  <Description>desc1</Description>
  <Description>desc2</Description>
</output>

A brief explanation of the part of the stylesheet that does the heavy lifting:

$file != ''
and
generate-id()
=
generate-id(key('kDescription', .)[../File = $file][1])

The first part is obvious - it's just there to make sure that a $file filter string was passed in.

The second part is plain Muenchian grouping with a little twist. It compares the IDs of two nodes, the current one (generate-id()) and one from the kDescription group, filtered by $file value.

kDescription indexes <Description> elements by their text value, which means that nodes with the same text but a different accompanying <File> will be returned by the call to key(). We need to filter them out.

If the current node is equal to the first node of the group that has the right <File> value, the test succeeds and something gets printed, otherwise nothing happens.

Tomalak
  • 332,285
  • 67
  • 532
  • 628
  • Thank you so very much for your prompt and useful answer. I really have so much to learn here. The XSL key being something that is defying me, also. Perhaps you could shed light here, as well: http://stackoverflow.com/questions/1621507/why-dont-all-xslt-templates-get-executed-at-once Thank you again, Matt. – Matt W Oct 25 '09 at 17:40
  • Hi Matt, glad to help. Regarding the xsl:key, I have written something up in my answer here (http://stackoverflow.com/questions/948218/xslt-3-level-grouping-on-attributes/955527#955527) that might help you understand. Read the lower part of my answer, understanding the question is not necessary in this case. I'm going to have a look at your other question now. – Tomalak Oct 25 '09 at 20:40
  • I see there is an answer there already. Ask if you still require further explanation. :) – Tomalak Oct 25 '09 at 22:24