How can we use rails routes with angularjs in a DRY way?

Question

First of all,I would say sorry for my broken English and the broken codes...(many words here come from google translation...so, I'm afraid that I can't make myself clear...so, I paste all the codes...)

Setting up routes in rails is really easy. But when we want to warp it into angurjs, it becomes a little bit verbose... Is there any 'best practice' for this kinds of job:

given some rails route resources:

resources :users
resources :photos
...
resources :topics

How to do it in angular side?

This is how I do (in coffee script, useing angular 1.1.4):

Use a RESTful service in Rails way:

# angular/services/restful.js.coffee
# RESTful resource following Rails route's convention
# index:  GET  '/resource.json'
# save:   POST '/resource.json'
# get:    GET  '/resource/:id.json'
# update: PUT  '/resource/:id.json'
# edit:   GET  '/resource/:id/edit.json'
# new:    GET   just use get, id: 'new'
app.factory('RESTful', ['$resource',
  ($resource)->
    (resource_name) ->
      url = "/#{resource_name}/:id:format"
      defaults={format: '.json', id: '@id'}

      actions = {
        index:
          id: ''
          url: "/#{resource_name}:format"
          method: 'GET'
          isArray:false
        edit:
          url: "/#{resource_name}/:id/edit:format"
          method: 'GET'
        update:
          method: 'PUT'
        save:
          url: "/#{resource_name}:format"
          method: 'POST'
      }

      $resource url, defaults, actions
])

# index:  GET  '/parents/:parent_id/children.json'
# save:   POST '/parents/:parent_id/children.json'
# get:    GET  '/parents/:parent_id/children/:id.json'
# update: PUT  '/parents/:parent_id/children/:id.json'
# edit:   GET  '/parents/:parent_id/children/:id/edit.json'
# new:    GET   just use get, id: 'new'
app.factory('NESTful', ['$resource',
  ($resource)->
    (parents, children) ->
      # naive singularize
      parent = parents.replace(/s$/, '')
      url = "/#{parents}/:#{parent}_id/#{children}/:id:format"

      defaults={ format: '.json', id: '@id' }

      actions = {
        index:
          id: ''
          url: "/#{parents}/:#{parent}_id/#{children}:format"
          method: 'GET'
          isArray:false
        edit:
          url: "/#{parents}/:#{parent}_id/#{children}/:id/edit:format"
          method: 'GET'
        update:
          method: 'PUT'
        save:
          url: "/#{parents}/:#{parent}_id/#{children}:format"
          method: 'POST'
      }

      $resource url, defaults, actions
])

Routes:

app.config(['$routeProvider', '$locationProvider', ($routeProvider, $locationProvider) ->
  $locationProvider.html5Mode(true)

  # general RESTful routes
  resource_list = ['users', 'photos', 'topics']
  for resource in resource_list
    # naive singularize
    singular = resource.replace(/s$/, "")
    captialize = singular.charAt(0).toUpperCase() + singular.slice(1)
    $routeProvider
      .when "/#{resource}",
          templateUrl: "/tp/#{resource}/index"
          controller: "#{captialize}IndexCtrl"
          resolve:
            index: ["#{captialize}Loader", (Loader)-> Loader('index')]
      .when "/#{resource}/new",
          templateUrl: "/tp/#{resource}/edit"
          controller: "#{captialize}NewCtrl"
          resolve:
            resource: ["#{captialize}Loader", (Loader)-> Loader('new')]
      .when "/#{resource}/:id",
          templateUrl: "/tp/#{resource}/show"
          controller: "#{captialize}ShowCtrl"
          resolve:
            resource: ["#{captialize}Loader", (Loader)-> Loader('show')]
      .when "/#{resource}/:id/edit",
          templateUrl: "/tp/#{resource}/edit"
          controller: "#{captialize}EditCtrl"
          resolve:
            resource: ["#{captialize}Loader", (Loader)-> Loader('edit')]

  # special routes
  $routeProvider
    .when '/',
        templateUrl: '/tp/pages/home'
        controller: 'PageCtrl'

    .otherwise({redirectTo: '/'})
])

The controller should be super clean and then we can focus on buisness

app.controller 'UserShowCtrl', ['$scope', 'resource'
  ($scope, resource)->
    $scope.user = resource.user
]
app.controller 'UserIndexCtrl', ['$scope', 'index',
  ($scope, index) ->
    $scope.users = index.resource.users
    $scope.total_pages = index.pages.total_pages
    $scope.currentPage = index.pages.current_page

    getPage = (page)->
      index.resource.$index
        page: page
        (resource, headers)->
          $scope.users = resource.users

    $scope.$watch 'currentPage', (newval)->
      getPage(newval)
]

The problem is in the Loader for resolve obj:

app.factory('UserLoader', ['RESTful', '$route', '$q',
  (RESTful, $route, $q) ->
    (action)->
      model = 'users'
      delay = $q.defer()
      fetcher = RESTful(model)
      switch action
        when 'index'
          fetcher.index
            page: $route.current.params.page
            (resource, headers)->
              delay.resolve
                resource: resource
                pages: JSON.parse(headers('X-Pagination'))
            (resource)->
              delay.reject "Unable to fetch #{model} index"
        when 'show'
          fetcher.get
            id: $route.current.params.id
            (resource)->
              delay.resolve(resource)
            (resource)->
              delay.reject "Unable to fetch #{model} #{$route.current.params.id}"
        when 'edit'
          fetcher.edit
            id: $route.current.params.id
            (resource)->
              delay.resolve(resource)
            (resource)->
              delay.reject "Unable to fetch #{model} #{$route.current.params.id} edit"
        when 'new'
          fetcher.get
            id: 'new'
            (resource)->
              delay.resolve(resource)
            (resource)->
              delay.reject "Unable to fetch #{model} new"

      return delay.promise
])

There are 2 problems here: The first problem is that I must copy && paste the above loader code and then gsub('user', 'photo'), etc... (Just change 2 words in fact, but I hate copy && paste..) I have tried moving it in a for loop which didn't work and I can't figure out why... Another problem is how to set up the nested resources,in a DRY way

Finally, thanks for your patience and I would say sorry again... But any solution, suggestion or best practices? Am I doing it wrong?

This question is much too large to attempt a reasonable response - as you have seen thus far. You may try instead to ask on codereview.stackexchange.com since that site focuses on code style — New Alexandria, May 28 '13 at 04:44

score 3 · Answer 1 · answered Jul 25 '13 at 05:25

Apart that your description of the question is very complicated (tons of code), I think you missed the point of REST API concept.

You are mixing your Rails backend resources (and its routing) with client-side routing. This is wrong IMHO. Your frontend app routes shouldn't be jumping (shadowing) over REST routes. If you are fetching users resource (for example GET /users/5.json) you shouldn't navigate your client to /tp/users/show. Your REST and client-side routes are two separate, independent abstractions.

Your client-side routes should be like

/
/userprofile
/dashboard
/articles/2013?page=4

And your Controllers sitting on those routes should use your resource services to fetch required data from REST API like this:

angular.module('myApp').controller 'UserProfileController', ($scope, userResource) ->
  $scope.user = userResource.query({id: SOME_ID})

angular.module('myApp.resources').factory 'userResource', ($resource) ->
  params = {
    id: '@id'
    subItem: '@subItem'
    subItemId: '@subItemId'
  }

  actions = {
    query: {
      method: 'GET'
      params: {}
      isArray: true
    }
    ban: {
      method: 'POST'
      params: {banned: true}
    }
  }

  return $resource('/api-1.0/users/:id/:subItem/:subItemId', params, actions)

Well, `/tp/user/show` is the templateUrl and templateUrl is definitely not the client route. In fact, you should never use the the same route in the templateUrl. Because when a user click a link from search engine, say `/users`, the server will just return the `index.html`, and the page is rendered in client side, and then angular will look for the templateUrl of `/users`, that cannot be `/users`,which returns `index.html` (that will cause a infinite loop and crash the broswer) — aptx4869, Jul 25 '13 at 08:35
About fetching data, well, useing a resolve object instead of loading data directly in controller would provide a better user experience （ it will prevent showing a broken page before data is fully loaded ) see [this question](http://stackoverflow.com/questions/11972026/delaying-angularjs-route-change-until-model-loaded-to-prevent-flicker) — aptx4869, Jul 25 '13 at 08:55
OK, thanks for comments. I studied your code very lightly during breakfast. — srigi, Jul 25 '13 at 12:28

score 0 · Answer 2 · answered Jul 25 '13 at 09:19

Well ,I figure out why the Loader for resolve doesn't work as expected... The key is that an angularjs service is a sigleton. It doesnt work because I put the loop inside the service definition in the first version...

for sort, this works:

angular.forEach [
  ['profile', 'profile']
  ['user', 'users']
  ['avatar', 'avatars']
],
(resouce_definition)->
  resource = resouce_definition[1]
  singular = resouce_definition[0]
  captialize = singular.charAt(0).toUpperCase() + singular.slice(1)
  app.factory("#{captialize}Loader", [
    'RESTful', '$route', '$q'
    (RESTful, $route, $q)->
      (action)->
        delay = $q.defer()
        id = $route.current.params.id
        fetcher = RESTful(resource)
        switch action
          when 'index'
            fetcher.index
              page: $route.current.params.page
              (response, headers)->
                delay.resolve
                  resource: response
                  pages: JSON.parse(headers('X-Pagination'))
              (response)->
                delay.reject "Unable to fetch #{resource} index"
          when 'show'
            fetcher.get
              id: id
              (response)->
                delay.resolve(response)
              (response)->
                delay.reject "Unable to fetch #{resource} #{id}"
          when 'edit'
            fetcher.edit
              id: id
              (response)->
                delay.resolve(response)
              (response)->
                delay.reject "Unable to fetch #{resource} #{id}"
          when 'new'
            fetcher.get
              id: 'new'
              (response)->
                delay.resolve(response)
              (response)->
                delay.reject "Unable to fetch #{resource} new"

        return delay.promise
  ])

score 0 · Answer 3 · answered Mar 30 '16 at 06:52

0

I try to avoid complex services like: '/parents/:parent_id/children/:id'
I separate this in two services:
/parents/:parent_id/children. For GET(list) and the POST(Id in Content) And then I have /children/id for the PUT,DELETE and single GET

answered Mar 30 '16 at 06:52

Jens Alenius

1,931
2
16
20

How can we use rails routes with angularjs in a DRY way?

Use a RESTful service in Rails way:

Routes:

The controller should be super clean and then we can focus on buisness

The problem is in the Loader for resolve obj:

3 Answers3

Linked