How to check if a process is running via a batch script

Question

How can I check if an application is running from a batch (well cmd) file?

I need to not launch another instance if a program is already running. (I can't change the app to make it single instance only.)

Also the application could be running as any user.

Possible duplicate of [Batch program to to check if process exists](http://stackoverflow.com/questions/15449034/batch-program-to-to-check-if-process-exists) — phuclv, Nov 29 '16 at 08:27
@LưuVĩnhPhúc I did. He's asking how to check if a program is running from batch script, while that other question asks how to get a task list. — Cardinal System, Apr 02 '17 at 02:41
@JackKirby then you should read again. Where in the other question that the OP said he wants to get a task list? He wants to check if a process is running — phuclv, Apr 02 '17 at 07:53
@oopsdazie yeah I may be wrong in this case but [the general rule is to keep the question with the best collection of answers, and close the other one as a duplicate](https://meta.stackexchange.com/q/10841/230282), irrespective of time — phuclv, May 18 '17 at 14:38

score 381 · Answer 1 · edited May 11 '21 at 22:23

381

Another possibility I came up with, which does not require to save a file, inspired by using grep is:

tasklist /fi "ImageName eq MyApp.exe" /fo csv 2>NUL | find /I "myapp.exe">NUL
if "%ERRORLEVEL%"=="0" echo Program is running

/fi "" defines a filter of apps to find, in our case it's the *.exe name
/fo csv defines the output format, csv is required because by default the name of the executable may be truncated if it is too long and thus wouldn't be matched by find later.
find /I means case-insensitive matching and may be omitted

See the man page of the tasklist command for the whole syntax.

edited May 11 '21 at 22:23

chwarr

6,777
1
30
57

answered Aug 25 '09 at 17:40

9

this worked for me nicely (windows XP SP3). IMHO this is the most elegant way of all proposed here, using just the tools shipped with windows – hello_earth Jul 08 '10 at 15:30
3

I had syntax problem with this command line. I changed it to `tasklist /FI "IMAGENAME eq winword.exe" 2>NUL | find /I /N "winword.exe">NUL` / `if %ERRORLEVEL%==1 goto wordnotrunning` in order to make it works (suspecting the quote around the if parts – Steve B Oct 19 '11 at 07:17
Works for me on Windows Server 2003! :) – Enrico Jul 05 '12 at 13:36
1

Thanks alot, man genius, can you please provide with code, if it is running then close aplication. – Mowgli Sep 15 '12 at 21:47
4

Please remember that in other language versions of XP the filter names were translated in code but not but in help `/?` screen. So for example `IMAGENAME` in polish version is `NAZWA_OBRAZU`. – rsk82 Nov 30 '12 at 15:44
3

Under Win7 I had to change it to `tasklist /FI "IMAGENAME eq myapp.exe" /NH | find /I /N "myapp.exe" >NUL` The first NUL seems unnecessary, I have no idea what the '2' is for, the /NH is optional. – Jan Doggen Nov 08 '13 at 09:17
14

tasklist always exits with status 0 whether or not it finds any matching tasks, which is why it's useless on its own. Since you have to use find (or findstr) to check its output anyway, there's no point using tasklist's filters. Just do tasklist | find "myprog.exe" >nul: && goto foundit or somesuch. You might need the /v (verbose) option to tasklist. – Denis Howe Jun 07 '14 at 12:32
1

Actually calling external find.exe is avoidable. See my reduced version nearby... – TrueY Aug 21 '14 at 10:21
@rsk82 In Win7 this seems to be pure English again (?) - at least on Polish Windows, `IMAGENAME` is working, while `NAZWA_OBRAZU` is not... – akavel Jan 08 '15 at 09:14
as stated by jan doggen, didn't work as is for me. The answer below by matt lacey worked for me without modifications. – Fractal Feb 18 '16 at 17:49
What happened to @ChaosMaster? – mtyson Sep 29 '16 at 22:55
I have no idea why, but I had to use `if errorlevel 0`, instead of `if "%ERRORLEVEL%"=="0"`. Oddly, using `%ERRORLEVEL%` works as expected if I issue the commands directly in `cmd.exe`, but if I try to do the same in a `.bat` script, `%ERRORLEVEL%` always evaluates to zero. FWIW, the script uses `setlocal enableextensions`; not sure if it's related to the observed behavior. This is on Windows 7 x64. – Ben Johnson Jul 10 '17 at 15:43
[should mention](https://stackoverflow.com/a/50299150/1037948) that if your taskname is too long the whole name won't appear in the results, so check for the opposite message instead – drzaus May 11 '18 at 19:40
A lot of superfluous bits. `tasklist | find /i "notepad.exe" > nul` is more than enough. – Jason Mar 22 '19 at 22:57
Just wanted to note down that I had gitbash installed and was seeing inconsistent results. Eventually tracked it down to VSCode running a node command had swapped system32 find for gitbash find. Solved once I used `C:\\Windows\\System32\\find.exe` I know it is a little verbose, but may be safest in the longrun. – WORMSS Feb 17 '20 at 00:14
@DenisHowe passing the whole task list to Find is noticeably slower than using TaskList's filter. – Richard Payne Mar 12 '20 at 15:34
@RichardPayne When exactly is the difference in speed worth the added complexity of filtering twice? – Denis Howe Mar 31 '20 at 10:29
@WORMSS The Windows findstr command is less likely to clash with added Unix commands. – Denis Howe Mar 31 '20 at 10:32
Its been ages since the answer is there. And this is the most elegant answer out there. Please mark this as the answer @mattlacey – Jun 20 '22 at 10:18
And if you'd like it to do something if it isn't found, you can use: `tasklist /fi "ImageName eq MyApp.exe" /fo csv 2>NUL | find /I "myapp.exe">NUL if "%ERRORLEVEL%"=="0" (echo Program is running) else (echo Not running)` – i Mr Oli i Jan 03 '23 at 14:35

score 64 · Answer 2 · edited Mar 05 '12 at 18:36

64

Here's how I've worked it out:

tasklist /FI "IMAGENAME eq notepad.exe" /FO CSV > search.log

FOR /F %%A IN (search.log) DO IF %%~zA EQU 0 GOTO end

start notepad.exe

:end

del search.log

The above will open Notepad if it is not already running.

Edit: Note that this won't find applications hidden from the tasklist. This will include any scheduled tasks running as a different user, as these are automatically hidden.

edited Mar 05 '12 at 18:36

Peter Mortensen

30,738
21
105
131

answered Oct 02 '08 at 13:49

Matt Lacey

65,560
11
91
143

2

Changing the tasklist format to CSV or anything but table is important because it tasklist default layout (table) truncates long image names which breaks the logic. – Scott White Jun 22 '11 at 14:56
4

This solution will not work on Vista because TASKLIST produces some output even if the process is not found. I presume the same is true for Windows 7. – dbenham Jan 28 '12 at 16:39
does not work in Windows 10. search.log contains "INFO: No tasks are running which match the specified criteria." and no notepad is started – Sergey May 30 '18 at 08:21
Creating a file needlessly, this is not the best way to perform this task – Mike Q Dec 13 '21 at 19:52

TrueY · Answer 3 · 2021-09-07T09:10:30.250

57

I like Chaosmaster's solution! But I looked for a solution which does not start another external program (like find.exe or findstr.exe). So I added the idea from Matt Lacey's solution, which creates an also avoidable temp file. At the end I could find a fairly simple solution, so I share it...

SETLOCAL EnableExtensions
set EXE=MyProg.exe
FOR /F %%x IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF NOT %%x == %EXE% (
  echo %EXE% is Not Running
)

This is working for me nicely...

The above is an edit. The original code apparently had a GOTO in it, which someone in the comments thought uncouth.

Spaces

If you are concerned that the program name may have spaces in it then you need to complicate the code very slightly:

SETLOCAL EnableExtensions
set EXE=My Prog.exe
FOR /F %%x IN ("%EXE%") do set EXE_=%%x
FOR /F %%x IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF NOT %%x == %EXE_% (
  echo %EXE% is Not Running
)

The original code will work fine whether or not other running processes have spaces in their names. The only concern is whether or not the process we are targeting has space(s).

ELSE

Keep in mind that if you add an ELSE clause then it will be executed once for every instance of the application that is already running. There is no guarantee that there be only a single instance running when you run this script.

Should you want one anyway, either a GOTO or a flag variable is indicated.

Ideally the targeted application should already mutex itself to prevent multiple instances, but that is a topic for another SO question and is not necessarily applicable to the subject of this question.

GOTO again

I do agree with the "ELSE" comment. The problem with the GOTO-less solution, that is may run the condition part (and the ELSE part) multiple times, so it is a bit messy as it has to quit the loop anyway. (Sorry, but I do not deal with the SPACE issue here, as it seems to be pretty rare and a solution is shown for it)

SETLOCAL EnableExtensions
SET EXE=MyProg.exe
REM for testing
REM SET EXE=svchost.exe
FOR /F %%x IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF NOT %%x == %EXE% (
  ECHO %EXE% is Not Running
  REM This GOTO may be not necessary
  GOTO notRunning
) ELSE (
  ECHO %EXE is running
  GOTO Running
)
...
:Running
REM If Running label not exists, it will loop over all found tasks

edited Sep 07 '21 at 09:10

answered Aug 21 '14 at 10:18

TrueY

7,360
1
41
46

This solution works well - tested in Windows 8.1. I did notice that it is case-sensitive. – m-smith Dec 02 '14 at 11:18
@LordScree As I work on un*x systems case sensitivity is good for me! I even set the file system to enable case sensitive file names. ;) – TrueY Dec 02 '14 at 12:42
Works well for me to - tested in windows 7 X64 – Mr Rubix Mar 15 '16 at 18:21
This doesn't work if the application has a space in the name as %x ends up being part of the application name up to the first space. – Chris Jun 14 '19 at 14:21
1

A possible solution would be to check if the application is not found instead by checking if %x == INFO: but I don't know which versions of Windows this would work on or if there's a better solution. – Chris Jun 14 '19 at 14:38
@Chris: This is also a good solution. If `%x == INFO`, it means that the program not found and Windows states `INFO: No tasks are running which match the specified criteria.`. But IMHO this is a bit less talkative. You can use both solution, of course! – TrueY Jun 17 '19 at 12:21
Why are we using goto here ? – Mike Q Aug 20 '21 at 16:54
@MikeQ If there is no goto, then it is going to fall to the "Not found" part. So, it has to be skipped somehow. Goto seems to be ok. – TrueY Aug 20 '21 at 19:42
@TrueY well it's generally not a good idea, I am going to update the solution to not use them. – Mike Q Aug 21 '21 at 19:00
@MikeQ Your no-goto evangelism broke it... How many times do we want to do something if multiple copies of the process is already running? Plus, OP only wants to do something if the process is _NOT_ running... I don't know how to revert an edit, so instead I updated it to also handle spaces in the process name, as per **Chris**'s suggestion. – Dúthomhas Sep 04 '21 at 08:17
@Dúthomhas I just wasted my time trying to figure out your trivial complaints , honestly if you are looking for efficient coding batch isn't for you. Not sure why you are getting so upset about your slightly "improved" code, what I wrote works and worked for me when I needed to confirm something running. – Mike Q Sep 05 '21 at 20:41
FWIW tasklist.exe is an external program. Not sure why find and findstr are undesirable while tasklist is ok. – Tim Sparkles Sep 02 '22 at 21:59
@TimSparkles Unfortunately `tasklist` is not replaceable with an internal command (as I know). But `findstr` can be eliminated. – TrueY Sep 05 '22 at 14:12

score 33 · Answer 4 · answered May 11 '17 at 17:57

33

The suggestion of npocmaka to use QPROCESS instead of TASKLIST is great but, its answer is so big and complex that I feel obligated to post a quite simplified version of it which, I guess, will solve the problem of most non-advanced users:

QPROCESS "myprocess.exe">NUL
IF %ERRORLEVEL% EQU 0 ECHO "Process running"

The code above was tested in Windows 7, with a user with administrator rigths.

answered May 11 '17 at 17:57

aldemarcalazans

1,309
13
16

1

I just used this idea to stop an automated process firing twice and it worked like a charm! – Davy C Mar 14 '18 at 10:23
I must say that unlike this command, the tasklist solutions not only look too complicated for such a simple query, but they also run a second or so and use tons of cpu! This is much better, also worked with no admin permissions (Windows Server 2012). – Eugene Marin Jun 21 '18 at 15:36
This seems to be the simplest and best solution (at least for me) as it works as-is when the application has spaces in the name. I'm curious what the limitations of this solution are and why it doesn't have more votes. – Chris Jun 14 '19 at 14:41
simple and practical – focus zheng Jun 28 '20 at 10:36
1

this do not list system process – Badr Elmers Nov 21 '21 at 23:52
1

QPROCESS is only available in Windows Server 2022, 2019, 2016, 2012 R2, and 2012 https://learn.microsoft.com/en-us/windows-server/administration/windows-commands/qprocess I tested with Windows 10 both with and without admin permissions and the command was not recognized. – Joseph Clovis Jun 10 '22 at 03:36

Riccardo La Marca · Answer 5 · 2018-03-15T16:51:18.763

27

TASKLIST | FINDSTR ProgramName || START "" "Path\ProgramName.exe"

edited Mar 15 '18 at 16:51

answered Jan 16 '17 at 19:59

Riccardo La Marca

775
5
15

4

This actually works great. Simple! Just be aware it's case sensitive unless you add `/i`. – Jason Mar 25 '19 at 16:21

score 21 · Answer 6 · answered Jan 24 '11 at 14:23

21

Under Windows you can use Windows Management Instrumentation (WMI) to ensure that no apps with the specified command line is launched, for example:

wmic process where (name="nmake.exe") get commandline | findstr /i /c:"/f load.mak" /c:"/f build.mak" > NUL && (echo THE BUILD HAS BEEN STARTED ALREADY! > %ALREADY_STARTED% & exit /b 1)

answered Jan 24 '11 at 14:23

vtrz

591
1
6
12

Note that WMIC requires administrative privileges; if you don't have it, then `Only the administrator group members can use WMIC.EXE.` followed by `Reason:Win32 Error: Access is denied.` – Jeroen Wiert Pluimers Feb 14 '12 at 09:48
i think this is best solution, because wmic gives you a complete command line launched and milion other informations... – Glavić May 23 '12 at 15:42

kayleeFrye_onDeck · Answer 7 · 2016-02-04T18:43:31.423

TrueY's answer seemed the most elegant solution, however, I had to do some messing around because I didn't understand what exactly was going on. Let me clear things up to hopefully save some time for the next person.

TrueY's modified Answer:

::Change the name of notepad.exe to the process .exe that you're trying to track
::Process names are CASE SENSITIVE, so notepad.exe works but Notepad.exe does NOT
::Do not change IMAGENAME
::You can Copy and Paste this into an empty batch file and change the name of
::notepad.exe to the process you'd like to track
::Also, some large programs take a while to no longer show as not running, so
::give this batch a few seconds timer to avoid a false result!!

@echo off
SETLOCAL EnableExtensions

set EXE=notepad.exe

FOR /F %%x IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF %%x == %EXE% goto ProcessFound

goto ProcessNotFound

:ProcessFound

echo %EXE% is running
goto END
:ProcessNotFound
echo %EXE% is not running
goto END
:END
echo Finished!

Anyway, I hope that helps. I know sometimes reading batch/command-line can be kind of confusing sometimes if you're kind of a newbie, like me.

This is great, worked flawlessly for me in Windows 10! – nevarDeath Feb 04 '23 at 05:28 — nevarDeath, Feb 04 '23 at 05:28

score 8 · Answer 8 · answered Dec 02 '08 at 18:29

8

I use PV.exe from http://www.teamcti.com/pview/prcview.htm installed in Program Files\PV with a batch file like this:

@echo off
PATH=%PATH%;%PROGRAMFILES%\PV;%PROGRAMFILES%\YourProgram
PV.EXE YourProgram.exe >nul
if ERRORLEVEL 1 goto Process_NotFound
:Process_Found
echo YourProgram is running
goto END
:Process_NotFound
echo YourProgram is not running
YourProgram.exe
goto END
:END

answered Dec 02 '08 at 18:29

1

this works for me on windows 7. 2nd line is the directory that contains the program, not the program itself. – Fabio Cionini Apr 16 '12 at 21:23
The link doesn't work anymore. I think I found the same tool here, but didn't download and test it out. Use at your own risk: https://www.portablefreeware.com/index.php?id=406 – kayleeFrye_onDeck Feb 07 '23 at 10:40

npocmaka · Answer 9 · 2014-08-08T20:11:28.403

I like the WMIC and TASKLIST tools but they are not available in home/basic editions of windows.Another way is to use QPROCESS command available on almost every windows machine (for the ones that have terminal services - I think only win XP without SP2 , so practialy every windows machine):

@echo off
:check_process
setlocal
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
set process_to_check=%~1
:: QPROCESS can display only the first 12 symbols of the running process
:: If other tool is used the line bellow could be deleted
set process_to_check=%process_to_check:~0,12%

QPROCESS * | find /i "%process_to_check%" >nul 2>&1 && (
    echo process %process_to_check%  is running
) || (
    echo process %process_to_check%  is not running
)
endlocal

QPROCESS command is not so powerful as TASKLIST and is limited in showing only 12 symbols of process name but should be taken into consideration if TASKLIST is not available.

More simple usage where it uses the name if the process as an argument (the .exe suffix is mandatory in this case where you pass the executable name):

@echo off
:check_process
setlocal
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
:: .exe suffix is mandatory
set "process_to_check=%~1"


QPROCESS "%process_to_check%" >nul 2>&1 && (
    echo process %process_to_check%  is running
) || (
    echo process %process_to_check%  is not running
)
endlocal

The difference between two ways of QPROCESS usage is that the QPROCESS * will list all processes while QPROCESS some.exe will filter only the processes for the current user.

Using WMI objects through windows script host exe instead of WMIC is also an option.It should on run also on every windows machine (excluding the ones where the WSH is turned off but this is a rare case).Here bat file that lists all processes through WMI classes and can be used instead of QPROCESS in the script above (it is a jscript/bat hybrid and should be saved as .bat):

@if (@X)==(@Y) @end /* JSCRIPT COMMENT **


@echo off
cscript //E:JScript //nologo "%~f0"
exit /b

************** end of JSCRIPT COMMENT **/


var winmgmts = GetObject("winmgmts:\\\\.\\root\\cimv2");
var colProcess = winmgmts.ExecQuery("Select * from Win32_Process");
var processes =  new Enumerator(colProcess);
for (;!processes.atEnd();processes.moveNext()) {
    var process=processes.item();
    WScript.Echo( process.processID + "   " + process.Name );
}

And a modification that will check if a process is running:

@if (@X)==(@Y) @end /* JSCRIPT COMMENT **


@echo off
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
set process_to_check=%~1

cscript //E:JScript //nologo "%~f0" | find /i "%process_to_check%" >nul 2>&1 && (
    echo process %process_to_check%  is running
) || (
    echo process %process_to_check%  is not running
)

exit /b

************** end of JSCRIPT COMMENT **/


var winmgmts = GetObject("winmgmts:\\\\.\\root\\cimv2");
var colProcess = winmgmts.ExecQuery("Select * from Win32_Process");
var processes =  new Enumerator(colProcess);
for (;!processes.atEnd();processes.moveNext()) {
    var process=processes.item();
    WScript.Echo( process.processID + "   " + process.Name );
}

The two options could be used on machines that have no TASKLIST.

The ultimate technique is using MSHTA . This will run on every windows machine from XP and above and does not depend on windows script host settings. the call of MSHTA could reduce a little bit the performance though (again should be saved as bat):

@if (@X)==(@Y) @end /* JSCRIPT COMMENT **
@echo off

setlocal
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running

set process_to_check=%~1


mshta "about:<script language='javascript' src='file://%~dpnxf0'></script>" | find /i "%process_to_check%" >nul 2>&1 && (
    echo process %process_to_check%  is running
) || (
    echo process %process_to_check%  is not running
)
endlocal
exit /b
************** end of JSCRIPT COMMENT **/


   var fso= new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1);


   var winmgmts = GetObject("winmgmts:\\\\.\\root\\cimv2");
   var colProcess = winmgmts.ExecQuery("Select * from Win32_Process");
   var processes =  new Enumerator(colProcess);
   for (;!processes.atEnd();processes.moveNext()) {
    var process=processes.item();
    fso.Write( process.processID + "   " + process.Name + "\n");
   }
   close();

score 6 · Answer 10 · edited May 23 '17 at 12:10

The answer provided by Matt Lacey works for Windows XP. However, in Windows Server 2003 the line

 tasklist /FI "IMAGENAME eq notepad.exe" /FO CSV > search.log

returns

INFO: No tasks are running which match the specified criteria.

which is then read as the process is running.

I don't have a heap of batch scripting experience, so my soulution is to then search for the process name in the search.log file and pump the results into another file and search that for any output.

tasklist /FI "IMAGENAME eq notepad.exe" /FO CSV > search.log

FINDSTR notepad.exe search.log > found.log

FOR /F %%A IN (found.log) DO IF %%~zA EQU 0 GOTO end

start notepad.exe

:end

del search.log
del found.log

I hope this helps someone else.

This works for Win 2008. +1 for No tasks are running which match the specified criteria. — Mangesh, Dec 10 '14 at 01:04

Motti · Answer 11 · 2008-10-02T13:57:59.667

2

I don't know how to do so with built in CMD but if you have grep you can try the following:

tasklist /FI "IMAGENAME eq myApp.exe" | grep myApp.exe
if ERRORLEVEL 1 echo "myApp is not running"

edited Oct 02 '08 at 13:57

answered Oct 02 '08 at 13:50

Motti

110,860
49
189
262

score 2 · Answer 12 · answered May 11 '18 at 19:38

Just mentioning, if your task name is really long then it won't appear in its entirety in the tasklist result, so it might be safer (other than localization) to check for the opposite.

Variation of this answer:

:: in case your task name is really long, check for the 'opposite' and find  the message when it's not there
tasklist /fi "imagename eq yourreallylongtasknamethatwontfitinthelist.exe" 2>NUL | find /I /N "no tasks are running">NUL
if "%errorlevel%"=="0" (
    echo Task Found
) else (
    echo Not Found Task
)

score 2 · Answer 13 · answered May 12 '21 at 08:39

If you have more than one .exe-file with the same name and you only want to check one of them (e.g. you care about C:\MyProject\bin\release\MyApplication.exe but not C:\MyProject\bin\debug\MyApplication.exe) then you can use the following:

@echo off

set "workdir=C:\MyProject\bin\release"
set "workdir=%workdir:\=\\%"

setlocal enableDelayedExpansion
for /f "usebackq tokens=* delims=" %%a in (`
    wmic process  where 'CommandLine like "%%!workdir!%%" and not CommandLine like "%%RuntimeBroker%%"'   get CommandLine^,ProcessId  /format:value
`) do (
    for /f "tokens=* delims=" %%G in ("%%a")  do (
        if "%%G" neq "" (
rem            echo %%G
            set "%%G"
rem            echo !ProcessId!
            goto :TheApplicationIsRunning
        )
    )
) 

echo The application is not running
exit /B

:TheApplicationIsRunning
echo The application is running
exit /B

Patrick · Answer 14 · 2020-04-24T18:28:11.940

I needed a solution with a retry. This code will run until the process is found and then kill it. You can set a timeout or anything if you like.

Notes:

The ".exe" is mandatory
You could make a file runnable with parameters, version below

    :: Set programm you want to kill
    :: Fileextension is mandatory
    SET KillProg=explorer.exe

    :: Set waiting time between 2 requests in seconds
    SET /A "_wait=3"

    :ProcessNotFound
        tasklist /NH /FI "IMAGENAME eq %KillProg%" | FIND /I "%KillProg%"
        IF "%ERRORLEVEL%"=="0" (
            TASKKILL.EXE /F /T /IM %KillProg%
        ) ELSE (
            timeout /t %_wait%
            GOTO :ProcessNotFound
        )

taskkill.bat:

    :: Get program name from argumentlist
    IF NOT "%~1"=="" (
        SET "KillProg=%~1"
    ) ELSE (
        ECHO Usage: "%~nx0" ProgramToKill.exe & EXIT /B
    )

    :: Set waiting time between 2 requests in seconds
    SET /A "_wait=3"

    :ProcessNotFound
        tasklist /NH /FI "IMAGENAME eq %KillProg%" | FIND /I "%KillProg%"
        IF "%ERRORLEVEL%"=="0" (
            TASKKILL.EXE /F /T /IM %KillProg%
        ) ELSE (
            timeout /t %_wait%
            GOTO :ProcessNotFound
        )

Run with .\taskkill.bat ProgramToKill.exe

score 0 · Answer 15 · answered Oct 02 '08 at 13:37

0

I'm assuming windows here. So, you'll need to use WMI to get that information. Check out The Scripting Guy's archives for a lot of examples on how to use WMI from a script.

answered Oct 02 '08 at 13:37

NotMe

87,343
27
171
245

score 0 · Answer 16 · edited May 23 '17 at 12:03

0

Building on vtrz's answer and Samuel Renkert's answer on an other topic, I came up with the following script that only runs %EXEC_CMD% if it isn't already running:

@echo off
set EXEC_CMD="rsync.exe"
wmic process where (name=%EXEC_CMD%) get commandline | findstr /i %EXEC_CMD%> NUL
if errorlevel 1 (
    %EXEC_CMD% ...
) else (
    @echo not starting %EXEC_CMD%: already running.
)

As was said before, this requires administrative privileges.

edited May 23 '17 at 12:03

Community

1
1

answered Sep 18 '13 at 13:44

Calimo

7,510
4
39
61

did not work for me, and i'm using an admin account. A DOS box appears with `Node - (computer name) ERROR: Description = Invalid query` – khaverim May 12 '14 at 19:14
1

Works just fine for me. – t31os Mar 06 '15 at 12:57
1

Works great for Windows 7 here. No issues. – galacticninja Jan 07 '20 at 06:33

score 0 · Answer 17 · edited May 23 '17 at 11:33

0

I used the script provided by Matt (2008-10-02). The only thing I had trouble with was that it wouldn't delete the search.log file. I expect because I had to cd to another location to start my program. I cd'd back to where the BAT file and search.log are, but it still wouldn't delete. So I resolved that by deleting the search.log file first instead of last.

del search.log

tasklist /FI "IMAGENAME eq myprog.exe" /FO CSV > search.log

FOR /F %%A IN (search.log) DO IF %%-zA EQU 0 GOTO end

cd "C:\Program Files\MyLoc\bin"

myprog.exe myuser mypwd

:end

edited May 23 '17 at 11:33

Community

1
1

answered Jun 23 '10 at 15:57

Nin

11

1

@Sebastian: There's a little extra information added here, so I'm inclined to leave it as an answer. – Bill the Lizard Oct 16 '10 at 03:55

score -1 · Answer 18 · answered Mar 22 '17 at 09:13

-1

I usually execute following command in cmd prompt to check if my program.exe is running or not:

tasklist | grep program

answered Mar 22 '17 at 09:13

Rajeev Jayaswal

1,423
1
20
22

score -3 · Answer 19 · edited Mar 05 '12 at 18:38

-3

You should check the parent process name, see The Code Project article about a .NET based solution**.

A non-programmatic way to check:

Launch Cmd.exe
Launch an application (for instance, c:\windows\notepad.exe)
Check properties of the Notepad.exe process in Process Explorer
Check for parent process (This shows cmd.exe)

The same can be checked by getting the parent process name.

edited Mar 05 '12 at 18:38

Peter Mortensen

30,738
21
105
131

answered Oct 02 '08 at 13:36

prakash

58,901
25
93
115

How to check if a process is running via a batch script

19 Answers19

Spaces

ELSE

GOTO again

Linked

Related