Capitalize first letter of each word in a selection using Vim

Question

In Vim, I know we can use ~ to capitalize a single char (as mentioned in this question), but is there a way to capitalize the first letter of each word in a selection using Vim?

For example, if I would like to change this

hello world from stack overflow

to

Hello World From Stack Overflow

how should I do it in Vim?

Can also be done with [sed](https://superuser.com/a/749174/86708) — jpaugh, Nov 08 '18 at 16:49
For anyone else who lands here but wants to capitalize the first letter in a VERTICAL selection covering multiple lines, just do `Ctrl+V`, make your vertical selection to select the first letters, then type `~` and every first letter in each line will now be capitalized. — Eric Mutta, Aug 05 '23 at 13:59

score 225 · Accepted Answer · edited Apr 22 '21 at 22:15

225

You can use the following substitution:

s/\<./\u&/g

\< matches the start of a word
. matches the first character of a word
\u tells Vim to uppercase the following character in the substitution string (&)
& means substitute whatever was matched on the left-hand side
g means substitute all matches, not only the first

edited Apr 22 '21 at 22:15

Matthias Braun

32,039
22
142
171

answered Jul 03 '13 at 06:05

Rohit Jain

209,639
45
409
525

I just had to do this and used a macro that I over-repeated and I knew there had to be some better way but I never though of regex. This is great. Thanks. – Isaac Nequittepas Apr 13 '16 at 19:39
6

to do it in entire file `%s/\<./\u&/g` – Gabriel Borges Oliveira Jul 09 '19 at 15:49

score 70 · Answer 2 · edited Aug 04 '21 at 10:05

:help case says:

To turn one line into title caps, make every first letter of a word
uppercase:
    : s/\v<(.)(\w*)/\u\1\L\2/g

Explanation:

:                      # Enter ex command line mode.

space                  # The space after the colon means that there is no
                       # address range i.e. line,line or % for entire
                       # file.

s/pattern/result/g     # The overall search and replace command uses
                       # forward slashes.  The g means to apply the
                       # change to every thing on the line. If there
                       # g is missing, then change just the first match
                       # is changed.

The pattern portion has this meaning:

\v                     # Means to enter very magic mode.
<                      # Find the beginning of a word boundary.
(.)                    # The first () construct is a capture group.
                       # Inside the () a single ., dot, means match any
                       #  character.
(\w*)                  # The second () capture group contains \w*. This
                       # means find one or more word characters. \w* is
                       # shorthand for [a-zA-Z0-9_].

The result or replacement portion has this meaning:

\u                     # Means to uppercase the following character.
\1                     # Each () capture group is assigned a number
                       # from 1 to 9. \1 or back slash one says use what
                       # I captured in the first capture group.
\L                     # Means to lowercase all the following characters.
\2                     # Use the second capture group

Result:

ROPER STATE PARK
Roper State Park

An alternate to the very magic mode:

: % s/\<\(.\)\(\w*\)/\u\1\L\2/g
# Each capture group requires a backslash to enable their meta
# character meaning i.e. "\(\)" versus "()".

This was the most interesting answer to me. I'd never seen the very magic mode. I thought I'd document the answer after I understood the answer. — Greg, Jan 17 '15 at 21:45
Additionally, this answer handles all lower case, all upper case, or mixed case strings. — Greg, Jan 17 '15 at 22:04
I used \S instead of \w for non-ascii characters: `s/\v<(.)(\S*)/\u\1\L\2/g` :-) — Regisz, Nov 11 '22 at 12:10

score 14 · Answer 3 · edited Dec 13 '13 at 12:52

14

The Vim Tips Wiki has a TwiddleCase mapping that toggles the visual selection to lower case, UPPER CASE, and Title Case.

If you add the TwiddleCase function to your .vimrc, then you just visually select the desired text and press the tilde character ~ to cycle through each case.

edited Dec 13 '13 at 12:52

Matthew Rankin

457,139
39
126
163

answered Jul 03 '13 at 06:13

Ingo Karkat

167,457
16
250
324

score 2 · Answer 4 · answered Jul 03 '13 at 12:03

2

Try This regex ..

s/ \w/ \u&/g

answered Jul 03 '13 at 12:03

Krishna

381
2
9

I liked the answer with the use of the `&` but it does not work if your string string is mixed case to begin with or all uppercase to begin with. – Greg Jan 17 '15 at 21:49

score 2 · Answer 5 · edited May 09 '20 at 12:32

Option 1. -- This mapping maps the key q to capitalize the letter at the cursor position, and then it moves to the start of the next word:

:map q gUlw

To use this, put the cursor at the start of the line and hit q once for each word to capitalize the first letter. If you want to leave the first letter the way it is, hit w instead to move to the next word.

Option 2. -- This mappings maps the key q to invert the case of the letter at the cursor position, and then it moves to the start of the next word:

:map q ~w

To use this, put the cursor at the start of the line hit q once for each word to invert the case of the first letter. If you want to leave the first letter the way it is, hit w instead to move to the next word.

Unmap mapping. -- To unmap (delete) the mapping assigned to the q key:

:unmap q

Why a mapping and not an actual macro? `qq~wq` and replay with `@q` followed by `@@` ? — D. Ben Knoble, May 09 '20 at 12:33

score 1 · Answer 6 · answered Jan 13 '16 at 20:07

1

There is also the very useful vim-titlecase plugin for this.

answered Jan 13 '16 at 20:07

Serge Stroobandt

28,495
9
107
102

Thanks. Smart Title Case works well for Sublime Text as well. https://github.com/mattstevens/sublime-titlecase – Joshua Pinter Apr 06 '17 at 20:55

score 1 · Answer 7 · answered Jan 04 '21 at 09:48

1

To restrict the modification to the visual selection we have to use something like:

:'<,'>s/\%V\<.\%V/\u&/g

\%V ............... see help for this

answered Jan 04 '21 at 09:48

SergioAraujo

11,069
3
50
40

score 0 · Answer 8 · answered Feb 01 '21 at 04:29

0

The following mapping causes g~ to "title case" selected text:

vnoremap g~ "tc<C-r>=substitute(@t, '\v<(.)(\S*)', '\u\1\L\2', 'g')<CR><Esc>

answered Feb 01 '21 at 04:29

aggu

93
2
7

score 0 · Answer 9 · answered Dec 12 '22 at 17:57

The fastest way to do what you want on a random string and retain some control of words that you generally do not want capitalized (eg: articles like of/and) is to use ~ to change the case of the first word and then w. to select and change each word in turn, bearing in mind you can skip the . (repeat char) if you don't want to capitalize a particular word.

Capitalize first letter of each word in a selection using Vim

9 Answers9

Linked