1

Looking at Select distinct by two properties in a list it is possible to use the DistinctBy extensionmethod with two properties. I tried to convert this to vb.net, but I'm not getting the expected results

Test Class:

Public Class Test
    Public Property Id As Integer
    Public Property Name As String

    Public Overrides Function ToString() As String
        Return Id & " - " & Name
    End Function
End Class

Test Method:

Private Sub RunTest()
    Dim TestList As New List(Of Test)

    TestList.Add(New Test() With {.Id = 1, .Name = "A"})
    TestList.Add(New Test() With {.Id = 2, .Name = "A"})
    TestList.Add(New Test() With {.Id = 3, .Name = "A"})
    TestList.Add(New Test() With {.Id = 1, .Name = "A"})
    TestList.Add(New Test() With {.Id = 1, .Name = "B"})
    TestList.Add(New Test() With {.Id = 1, .Name = "A"})

    Dim Result As IEnumerable(Of Test)

    Result = TestList.DistinctBy(Function(element) element.Id)
    '1 - A
    '2 - A
    '3 - A

    Result = TestList.DistinctBy(Function(element) element.Name)
    '1 - A
    '1 - B

    Result = TestList.DistinctBy(Function(element) New With {element.Id, element.Name})
    '1 - A
    '2 - A
    '3 - A
    '1 - A
    '1 - B
    '1 - A

    'Expected:
    '1 - A
    '2 - A
    '3 - A
    '1 - B
End Sub

Is this at all possible in vb.net using anonymous types? Doing something like this:

Result = TestList.DistinctBy(Function(element) element.Id & "-" & element.Name)

is working, therefore I'm guessing I'm missing something with equality in anonymous types here.

Community
  • 1
  • 1
Keeper
  • 920
  • 1
  • 10
  • 16
  • What's the error message you're getting? Your code should work just fine. – MarcinJuraszek Jan 27 '14 at 17:26
  • Yes. You need to add Key before properties to compare two anonymous type instances for equality. – Jignesh Thakker Jan 27 '14 at 17:39
  • See the documentation for anonymous types in VB for more details at http://msdn.microsoft.com/en-us/library/bb384767.aspx – Jignesh Thakker Jan 27 '14 at 17:40
  • @MarcinJuraszek The code is working fine, yes. But the last Result is different from what I'm looking for (both outputs are in the code above). Using the Key-Keyword is working perfectly now! – Keeper Jan 27 '14 at 20:44

1 Answers1

1

You need to write Key before property. like

New With {Key element.Id, Key element.Name} in VB.

So,

Result = TestList.DistinctBy(Function(element) New With {Key element.Id, Key element.Name})

See the documentation for anonymous types in VB for more details.

Jignesh Thakker
  • 3,638
  • 2
  • 28
  • 35