Listen on specific host using warp

Question

When running a warp application using run, it listens on all IP adresses.

For security reasons, I want to listen on localhost only, handling remote access using a reverse proxy.

How do I need to call run to only listen on a specific host/IP?

Note: This question intentionally shows no research effort as it was answered Q&A-Style.

score 6 · Accepted Answer · answered May 05 '14 at 20:11

The currently accepted answer got broken by changes to conduit and/or warp. Warp no longer exports a Host constructor. But you don't need it, because the HostPreference type supports the OverloadedStrings extension, so you can just use a string directly.

This example also eliminates the deprecation warnings by switching to setPort and setHost.

{-# LANGUAGE OverloadedStrings #-}

import Network.Wai (responseLBS)
import Network.Wai.Handler.Warp
import Network.HTTP.Types (status200)
import Network.HTTP.Types.Header (hContentType)

main = do
    let port = 3000
    putStrLn $ "Listening on port " ++ show port
    let settings = setPort port $ setHost "127.0.0.1" defaultSettings
    runSettings settings app

app req = return $
    responseLBS status200 [(hContentType, "text/plain")] "Hello world!"

Thanks for updating to the latest API! I actually updated my own code a long time ago but forgot to update my answer accordingly. I'll mark your answer as accepted! — Uli Köhler, May 05 '14 at 22:03
You can also use `fromString`. Strangely, `read` doesn't work. — CMCDragonkai, Mar 10 '20 at 13:36

score 2 · Answer 2 · edited May 23 '17 at 12:06

run itself can't do that. you need to use runSettings:

The Settings parameter you want to pass it contains the information about the hosts it listens on.

The relevant type here is HostPreference. Although it allows you to specify different wildcards, including IPv6Only, we'll use the Host constructor here.

Based on this answer, I'll show a minimal example to listen on localhost only.

Note that accessors like settingsHost are marked deprecated, but the official documentation for warp 2.1.2.1 still shows an example using settingsTimeout here.

{-# LANGUAGE OverloadedStrings #-}

import Network.Wai (responseLBS)
import Network.Wai.Handler.Warp
import Network.HTTP.Types (status200)
import Network.HTTP.Types.Header (hContentType)

main = do
    let port = 3000
    putStrLn $ "Listening on port " ++ show port
    let settings = defaultSettings { settingsPort = port,
                                     settingsHost = Host "127.0.0.1" }
    runSettings settings app

app req = return $
    responseLBS status200 [(hContentType, "text/plain")] "Hello world!"

Please explain the downvote, just downvoting this won't make the post any better! — Uli Köhler, Mar 25 '14 at 14:27
As far as I can tell, `Network.Wai.Handler.Warp` doesn't export the `Host` constructor, at least not anymore. — Ed4, May 05 '14 at 18:07

Listen on specific host using warp

2 Answers2

Linked