Visual Basic - system.nullReferenceException

Question

So I'm still a bit of a newbie when it comes to programming, hence why I'm using visual basic. I'm getting this exception raised repeatedly, but the variables that vb is saying have unassigned values have been given values in my code. Can anyone point out where I'm going wrong with this?

EDIT: just a few more details: the file exists, I can read from it using just the ReadLine method, but I need to split the fields so I can compare the scores and get the highest 2 scores

Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load

    Dim srdFile As System.IO.StreamReader
    Dim strLine As String
    Dim strField(1) As String
    Dim strName() As String
    Dim strScore() As String
    Dim i = 0

    srdFile = New System.IO.StreamReader("HighScores.dat")
    rtbOut.AppendText("HighScores:" & vbNewLine & vbNewLine)

    Do Until srdFile.Peek() = -1

            strLine = srdFile.ReadLine()
            strField = strLine.Split(",")

            strName(i) = strField(0)
            strScore(i) = strField(1)

            rtbOut.AppendText(strName(i) & ", " & strScore(i) & vbNewLine)

            i = i + 1

    Loop
End Sub

What variable is unassigned? Btw, i recommend to set `Option Strict` to `On` by default. — Tim Schmelter, Sep 08 '14 at 08:44
Welcome to Stack Overflow! Almost all cases of `NullReferenceException` are the same. Please see "[What is a NullReferenceException in .NET?](http://stackoverflow.com/questions/4660142/what-is-a-nullreferenceexception-in-net)" for some hints. — John Saunders, Sep 08 '14 at 09:12

Tim Schmelter · Answer 1 · 2014-09-08T08:58:03.070

Following two arrays are never initialized: strName and strScore

I don't know the logic, but one way would be to use a List(Of String) instead which does not need to get the correct size in the first place and can be resized. I would also use the Using-statement to dispose the stream properly:

Using srdFile As New System.IO.StreamReader("HighScores.dat")
    Dim strLine As String
    Dim strField(1) As String
    Dim strName As New List(Of String)
    Dim strScore As New List(Of String)
    Dim i = 0

    rtbOut.AppendText("HighScores:" & vbNewLine & vbNewLine)
    Do Until srdFile.Peek() = -1
        strLine = srdFile.ReadLine()
        strField = strLine.Split(","c)
        strName.Add(strField(0))
        strScore.Add(strField(1))

        rtbOut.AppendText(strName(i) & ", " & strScore(i) & vbNewLine)
        i += 1
    Loop
End Using

Side-note: i recommend to set Option Strict to On by default.

By the way, here is a completely different approach doing the same but with LINQ:

Dim lines = From line In IO.File.ReadLines("HighScores.dat")
            Where Not String.IsNullOrWhiteSpace(line)
            Let fields = line.Split(","c)
            Let name = fields.First()
            Let score = fields.Last()
            Select String.Format("{0}, {1}", name, score)
rtbOut.Text = String.Join(Environment.NewLine, lines)

I find this more readable.

I tried compiling your code but I got build errors. I just don't understand why the variable is being read as null, the loop is definitely executing, as I tried outputting "test" directly to the rtb from the file. The problem is splitting the file into separate arrays. They are being given a value, so why am I getting a null exception? — Keelan Pool, Sep 08 '14 at 09:22
@keelan1234: _what_ build errors do you get? It should at least compile. What framework( or VisualStudio-version ) are you using? You have declared these arrays but you have never initialized them, that's why they are still `Nothing` which raises the exception when you try to acess them(f.e. `strName(i)`). You could initialize it in this way: `Dim strName(1) As String`. But then the array can only contain two strings. Does my second approach work? — Tim Schmelter, Sep 08 '14 at 09:27
I don't understand your code, not how I have learnt, so I'd like to use my code if possible. I'm using VS 2010, and I think in the interim I'm just going to give the array a size of 2, and rather than storing all scores I can check if the score being submitted is higher than the current 2 high scores, and if not then it can just be discarded. — Keelan Pool, Sep 08 '14 at 09:54

score 0 · Answer 2 · edited May 23 '17 at 10:29

Before you use an array, you need to assign a fixed array size in the computer memory locations. You can do this by initialising an array with the number of array elements. In your code, you have not allocated any memory to strName() and strScore() before using them, hence the code will throw an exception.

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    Dim srdFile As System.IO.StreamReader
    Dim strLine As String
    Dim strField(1) As String
    Dim strName(10) As String ''fixed size array (Using List(Of T) is a better option)
    Dim strScore(10) As String ''fixed size array (Using List(Of T) is a better option)
    Dim i = 0

    srdFile = New System.IO.StreamReader("HighScores.dat")
    rtbOut.AppendText("HighScores:" & vbNewLine & vbNewLine)

    Do Until srdFile.Peek() = -1

        strLine = srdFile.ReadLine()
        strField = strLine.Split(",")

        strName(i) = strField(0)
        strScore(i) = strField(1)

        rtbOut.AppendText(strName(i) & ", " & strScore(i) & vbNewLine)

        i = i + 1

    Loop
End Sub

You can also create a dynamic array. Please follow Resizing an array at runtime in VB.NET on Stackoverflow about dynamic array.

Please consider suggesting the use of a `List(Of T)` rather than resizing arrays. — Andrew Morton, Jun 12 '16 at 12:24
Thanks Andrew. I totally agree, List(Of T) is better option than resizing an array. List(Of T) takes care of dynamic memory allocation by itself and saves a lot of codes. — Gaurang, Jun 12 '16 at 12:45

Visual Basic - system.nullReferenceException

2 Answers2