XML XSLT -> HTML Transformation - How to split xml element text into dot points with xslt

Question

I have a XML data structure that I am transforming with XSLT into HTML. I need to split the text in the current_teaching element of my XML into dot points (semi-colons in the element content indicate where I would like the splitting to occur) with XSLT and output.

So far this is what I have.

XML/XSLT FILE:

        <?xml version="1.0" encoding="UTF-8"?>
    <?xml-stylesheet type="text/xsl" href="StaffList.xslt"?>
    <StaffList>
        <StaffMember>
            <title>Dr John Brown</title>
            <titledesc>Senior Lecturer, ICU Security Research Institute</titledesc>       <!-- example text --> 
            <telephone>(645) 2545 6988</telephone>
            <mobile>04568 6665 666</mobile>
            <facsimile>(61 8) 9999 9999</facsimile>
            <email>dr.brown@brown.com</email>
            <campus>Mountain Range</campus> 
            <room>18.13</room>
            <description>John Brown is a awesome doctor.</description>
            <current_teaching>Data Structures; Principles of Distributed Systems; Fundamentals of Software Engineering</current_teaching> 
        </StaffMember>
    </StaffList>

XSLT:



   <?xml version="1.0" encoding="ISO-8859-1"?>
    <xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/">
     <html>
      <head>
              <link rel="stylesheet" type="text/css" href="StaffList.css"/>
     </head>
     <body>
       <xsl:for-each select="StaffList/StaffMember">
        <h2 id="title"><xsl:value-of select="title"/></h2>
        <h3 id="titledesc"><xsl:value-of select="titledesc"/></h3>
        <br></br>
       <table>
         <tr>
         <td id="telephone_1">Telephone</td>
          <td id="telephone_2"><xsl:value-of select="telephone"/></td>
         </tr>
         <tr>
         <td id="mobile_1">Mobile</td>
         <td id="mobile_2"><xsl:value-of select="mobile"/></td>
        </tr>
        <tr>
        <td id="facsimile_1">Facsimile</td>
        <td id="facsimile_2"><xsl:value-of select="facsimile"/></td>
        </tr>
        <tr>
        <td id="email_1">Email</td>
        <td id="email_2"><xsl:value-of select="email"/></td>
        </tr>
        <tr>
        <td id="campus_1">Campus</td>
        <td id="campus_2"><xsl:value-of select="campus"/></td>
        </tr>
        <tr>
        <td id="room_1">Room</td>
        <td id="room_2"><xsl:value-of select="room"/></td>
        </tr>   
       </table>
       <br></br>
       <br></br>
       <p><xsl:value-of select="description"/></p>
       <br></br>

        </xsl:for-each>
     </body>
     </html>
    </xsl:template></xsl:stylesheet>

I did some searching and already found a possible solution but I could not get my XSLT to work with it. Here is what I tried:

        <ul>
        <xsl:analyze-string select="string()" regex=".*?[\.;]" flags="sm">
            <xsl:matching-substring>
                <li><xsl:value-of select="."/></li>
            </xsl:matching-substring>
            <xsl:non-matching-substring>
                <li><xsl:value-of select="."/></li>
            </xsl:non-matching-substring>
        </xsl:analyze-string>
    </ul>

This was added in-between the last br /br and /xsl:for-each of the XSLT code above.

Your stylesheet declares version 1.0. You are trying to use `xsl:analyze-string` which requires XSLT 2.0. Which XSLT processor are you actually using? — michael.hor257k, Apr 04 '15 at 18:51
I'm using 1.0 at the moment, is it as simple as just changing the declaration to switch to 2.0? — user2285167, Apr 04 '15 at 19:12
No, you need an XSLT 2.0 processor to use XSLT 2.0 features. Which specific XSLT 1.0 processor are you using? If you're not sure, find out - see here how: http://stackoverflow.com/questions/25244370/ — michael.hor257k, Apr 04 '15 at 19:21

Dimitre Novatchev · Accepted Answer · 2015-04-04T23:53:35.163

The XSLT 1.0 tokenizing template can be very short and simple, proving that <xsl:choose>, <xsl:when> and <xsl:otherwise> can be avoided:

<xsl:template match="current_teaching/text()[normalize-space()]" name="split">
  <xsl:param name="pText" select="."/>
  <xsl:if test="normalize-space($pText)">
    <li><xsl:value-of select="substring-before(concat($pText, ';'), ';')"/></li>
    <xsl:call-template name="split">
      <xsl:with-param name="pText" select="substring-after($pText, ';')"/>
    </xsl:call-template>
  </xsl:if>
</xsl:template>

And it will typically be selected for execution, using an <xsl:apply-templates> instruction from your code simply like this:

   <ul>
     <xsl:apply-templates select="current_teaching"/>
   </ul>

Explanation: What helps eliminate complexity in this solution is using the principle of Sentinel Programming. One sentinel character (;) is appended to the string, and this eliminates the need to analyze two separate cases -- when the text contains the delimiter, and when the text doesn't contain the delimiter.

score 1 · Answer 2 · answered Apr 04 '15 at 20:16

In XSLT 1.0 (which is all a Microsoft processor will support), you need to call a named template to recursively process the input. The call would look something like:

<ul>
    <xsl:call-template name="tokenize">
        <xsl:with-param name="text" select="current_teaching"/>
    </xsl:call-template>
</ul>

and the named template:

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="'; '"/>
    <xsl:choose>
        <xsl:when test="contains($text, $delimiter)">
            <li>
                <xsl:value-of select="substring-before($text, $delimiter)"/>
            </li>
            <!-- recursive call -->
            <xsl:call-template name="tokenize">
                <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <li>
                <xsl:value-of select="$text"/>
            </li>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

XML XSLT -> HTML Transformation - How to split xml element text into dot points with xslt

2 Answers2

Linked