Split into words by an uncommented comma that is not inside matching parentheses

Question

Consider the following string:

blah, foo(a,b), bar(c,d), yo

I want to extract a list of strings:

blah
foo(a,b)
bar(c,d)
yo

It seems to me that I should be able to use quote words here, but I'm struggling with the regex. Can someone help me out?

I added a solution that handles nested parentheses. It's probably slower than @stribizhev's, though, so if you don't need to handle that, use theirs. — Lynn, Jul 10 '15 at 10:08
Also, wild guess, but for the string you wrote, you can simply split on `, ` (note the space). The inner "arguments" don't contain spaces. If your input is like that too, you might as well just do that. — Lynn, Jul 10 '15 at 10:10

Lynn · Accepted Answer · 2015-07-10T10:27:07.203

3

Perl has a little thing regex recursion, so you might be able to look for:

either a bare word like blah containing no parentheses (\w+)
a "call", like \w+\((?R)(, *(?R))*\)

The total regex is (\w+(\((?R)(, ?(?R))*\))?), which seems to work.

edited Jul 10 '15 at 10:27

answered Jul 10 '15 at 10:05

Lynn

10,425
43
75

1

A better and cleaner way i would say – vks Jul 10 '15 at 10:23

Wiktor Stribiżew · Answer 2 · 2015-07-10T10:15:16.473

1

You can use the following regex to use in split:

\([^()]*\)(*SKIP)(*F)|\s*,\s*

With \([^()]*\), we match a ( followed with 0 or more characters other than ( or ) and then followed with ). We fail the match with (*SKIP)(*F) if that parenthetical construction is found, and then we only match the comma surrounded with optional whitespaces.

See demo

#!/usr/bin/perl
my $string= "blah, foo(a,b), bar(c,d), yo";
my @string = split /\([^()]*\)(*SKIP)(*F)|\s*,\s*/, $string;

foreach(@string) {
    print "$_\n";
}

To account for commas inside nested balanced parentheses, you can use

my @string = split /\((?>[^()]|(?R))*\)(*SKIP)(*F)|\s*,\s*/, $string;

Here is an IDEONE demo

With \((?>[^()]|(?R))*\) we match all balanced ()s and fail the match if found with the verbs (*SKIP)(*F), and then we match a comma with optional whitespace around (so as not to manually trim the strings later).

For a blah, foo(b, (a,b)), bar(c,d), yo string, the result is:

blah
foo(b, (a,b))
bar(c,d)
yo

edited Jul 10 '15 at 10:15

answered Jul 10 '15 at 10:01

Wiktor Stribiżew

607,720
39
448
563

1

This doesn't handle `blah, foo(a, bar(b, c)), yo`, but I'm not sure if the OP needs it to. – Lynn Jul 10 '15 at 10:02
@Mauris: That is easy to fix as you see. – Wiktor Stribiżew Jul 10 '15 at 10:18
@stribizhev your fix hasnt made any change it seems https://regex101.com/r/hR7tH4/8 – vks Jul 10 '15 at 10:23
@vks: PCRE and Perl are different a bit, it works in Perl. – Wiktor Stribiżew Jul 10 '15 at 10:34

score 1 · Answer 3 · edited May 23 '17 at 11:58

1

There is a solution given by Borodin for one of your question (which is similar to this question). A small change of regex will give you desire output: (this will not work for nested parentheses)

use strict;
use warnings;
use 5.010;

my $line = q<blah, foo(a,b), bar(c,d), yo>;

my @words = $line =~ / (?: \([^)]*\) | [^,] )+ /xg;

say for @words;

Output:

blah
 foo(a,b)
 bar(c,d)
 yo

edited May 23 '17 at 11:58

Community

1
1

answered Jul 10 '15 at 10:51

serenesat

4,611
10
37
53

Split into words by an uncommented comma that is not inside matching parentheses

3 Answers3