Determine Width of TLabel

Question

Hello Stack Overflow Users

I have a TGroupBox with a TLabel in it. With this TLabel I want to display the surname and names of a candidate. Some candidates have more than one name, sometimes three, and when that happens, the TLabel doesn't always fit inside my TGroupBox. When that happens, I only display the surname, the first name, and the rest I only as initials.

In order to do this, I need to know whether the TLabel is going to fit if the values were to be assigned to it. In other words, I need to determine what the width of the TLabel is going to be before actually assigning the values to its Caption property, for that would be bad programming to display variable data.

Any suggestions?

Are you using VCL or FMX? – Remy Lebeau Sep 30 '15 at 17:09 — Remy Lebeau, Sep 30 '15 at 17:09

score 2 · Accepted Answer · answered Oct 03 '15 at 14:08

I found a very easy and short way to do this. Basically, you just want to know the width of a string in pixels, so the best way to achieve this is to dynamically create an object that has a Font and Canvas property. I thought TBitmap will be the best option. Here’s the code I used:

var
  sString: string;
  bmWidth: TBitmap;
  iWidth: Integer;
begin
  sString := edtEdit.Text;
  bmWidth := TBitmap.Create;
  try
    bmWidth.Canvas.Font.Assign(lblLabel.Font);
    iWidth := bmWidth.Canvas.TextWidth(sString);
  finally
    bmWidth.Free;
  end;
end;

Remy Lebeau · Answer 2 · 2015-09-30T20:00:34.683

In VCL, TLabel uses the Win32 API DrawText() function to calculate the text width, using GetDC() to get the HDC of the screen and then SelectObject() to select its current Font into that HDC. You will have to do the same in your own code, eg:

// set Label1.AutoSize to False and Label1.Width to
// the max width your UI will accept the Label1 to be...

function WillFitInLabel(Label: TLabel; const S: String): Boolean;
var
  R: TRect;
  C: TCanvas;
  DC: HDC;
begin
  R := Rect(0, 0, Label.Width, 0);
  C := TCanvas.Create;
  try
    DC := GetDC(0);
    try
      C.Handle := DC;
      try
        C.Font := Label1.Font;
        Windows.DrawText(DC, PChar(S), Length(S), R, DT_SINGLELINE or DT_CALCRECT);
      finally
        C.Handle := 0;
      end;
    finally
      ReleaseDC(0, DC);
    end;
  finally
    C.Free;
  end;
  Result := (R.Width <= Label.Width);
end;

var
  Names: String;
begin
  Names := ...;
  if WillFitInLabel(Label1, Names) then
    Label1.Caption := Names
  else
    ...
end;

See also `TCanvas.TextWidth` ([VCL](http://docwiki.embarcadero.com/Libraries/en/Vcl.Graphics.TCustomCanvas.TextWidth) and [FMX](http://docwiki.embarcadero.com/Libraries/en/FMX.Graphics.TCanvas.TextWidth)). — Rob Kennedy, Sep 30 '15 at 20:32
In VCL, `TCanvas.TextWidth()` uses the Win32 `GetTextExtentPoint32()` function, which does not calculate things the same way that the Win32 `DrawText()` function does. `TLabel` uses `DrawText()` for both calculations and drawing. — Remy Lebeau, Sep 30 '15 at 23:06

score -1 · Answer 3 · answered Oct 02 '15 at 15:34

-1

If you want wrapping long text in multi lines then you can use label's property WordWrap := True and AutoSize := True.

answered Oct 02 '15 at 15:34

JayDi

1,037
15
24

Determine Width of TLabel

3 Answers3