FORFILES: Only delete file if RELPATH contains substring

Question

In another topic I found the following code snippet to check if a string contains a substring.

if not x%str1:bcd=%==x%str1% echo It contains bcd

Now I am trying to implement this in my FORFILES method. FORFILES should delete XML files that are in a subfolder that contains the substring 'IMG'. I adapted the code as follows:

set loglocation=C:\Tools\PurgeOldFiles\log\DELETEOLD_XML_IMG.txt
set olderthan=30
set source=X:\Test
set extension=XML

FORFILES -p%source% -s -m*.%extension% -d-%olderthan% -c"CMD /C if not x@RELPATH:img=%==x@RELPATH DEL @PATH\@FILE /q & echo @PATH\@FILE deleted." >> %loglocation%

It does not delete the old (older than 30 days) XML files in an IMG subfolder.

I guess that I have some kind of (syntax) error in "x@RELPATH:img=%==x@RELPATH".

Answer 1

You will need an interim environment variable, say VAR, and delayed expansion to accomplish that.

---

At first let us build the code that needs to be executed in the forfiles loop:

if @isdir==FALSE (
    set VAR=@relpath
    if not #!VAR:%search%=!==#!VAR! (
        del /Q @path
        echo @path deleted.
    )
)

This does the following steps:

• check whether the matched item is a file, skip the rest otherwise;
• assign the value of @relpath to the variable VAR; note that @relpath is expanded to a relative path enclosed in "";
• check whether the expanded relative path contains at least one instance of the search string, skip the rest if not; note that the search is done in a case-insensitive manner;
• delete the matched path, return the related log message; @path already contains the file name plus extension, so you do not need @file;

---

Now let us write the above code as a single line and put it together with forfiles:

set "loglocation=C:\Tools\PurgeOldFiles\log\DELETEOLD_XML_IMG.txt"
set "olderthan=30"
set "source=X:\Test"
set "extension=XML"
set "search=img"

forfiles /S /P "%source%" /M "*.%extension%" /D -%olderthan% /C "cmd /V:ON /C 0x22if @isdir==FALSE ((set VAR=@relpath) & if not #!VAR:%search%=!==#!VAR! (del /Q @path & echo @path deleted.))0x22" >> "%loglocation%"

The /V switch of cmd enables delayed expansion; the !VAR! syntax makes use of it (opposed to %VAR%). Type cmd /? for more information on that.

---

Notes:

The search for the img substring does not care about where (at which level in the path) a match is found, nor does it detect how many matches occur.

Be aware that the switch /S of forfiles makes it to enumerate the given directory recursively.

Answer 2

You cannot do a find/replace directly on a FORFILES variable. I would use FINDSTR with a regular expression to determine if the folder path includes IMG. You can redirect the output to NUL and conditionally execute commands only when found by using &&.

Other issues:

• You only need @PATH in your DEL and log statements - it contains the full path, including file name.
• The DEL /Q option is not needed since there is no wildcard.
• You should only echo the delete message if the DEL is successful. But DEL does not set the errorlevel or activate || if it fails, even though it prints an error message to stderr. You can redirect the DEL stderr to stdout and pipe to FINDSTR to determine if there was an error message, and use || and && to take appropriate action.

You are not clear if you want to delete the file if IMG is anywhere within the path, or only if it is in the parent folder.

The following deletes files if IMG appears anywhere in the folder path:

set loglocation=C:\Tools\PurgeOldFiles\log\DELETEOLD_XML_IMG.txt
set olderthan=30
set source=X:\Test
set extension=XML

forfiles /p "%source%" /s /m "*.%extension%" /d -%olderthan% /c "cmd /c echo @RELPATH|findstr /i IMG.*[\\] >nul &&(del @PATH 2>&1|findstr 0x22^0x22>nul&&echo unable to delete @PATH||echo deleted @PATH)"  >>"%loglocation%"

A bit more complex regex restricts deletes to only when IMG appears in the parent folder

set loglocation=C:\Tools\PurgeOldFiles\log\DELETEOLD_XML_IMG.txt
set olderthan=30
set source=X:\Test
set extension=XML

forfiles /p "%source%" /s /m "*.%extension%" /d -%olderthan% /c "cmd /c echo @RELPATH|findstr /i 0x22IMG[^\\]*[\\][^\\]*$0x22 >nul &&(del @PATH 2>&1|findstr 0x22^0x22>nul&&echo unable to delete @PATH||echo deleted @PATH)"  >>"%loglocation%"