xslt transformation : create a text file

Question

Below is the xml

<?xml version="1.0" encoding="utf-8"?>
<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
    xmlns:ser="http://xyz.com.zr/l8q/12Q/service/">
    <soapenv:Header>
        <ser:User>
            <!-- comment -->
            <Username/>
            <password/>
        </ser:User>
    </soapenv:Header>
    <soapenv:Body>
        <mainTag>
            <abc>1596056</abc>
            <asd>12434F</asd>
            <def>wert</def>
            <childtag>
                <asdf>1233</asdf>
                <qwe>567</qwe>
            </childtag>
        </mainTag>
    </soapenv:Body>
</soapenv:Envelope>

Below is my XSLT

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text" omit-xml-declaration="yes" indent="no"/>

    <xsl:template match="mainTag">
        <xsl:result-document href="foo.txt" method="text">
            01|<xsl:value-of select="abc"/>|<xsl:value-of select="asd"/>|<xsl:value-of select="childtag/asdf"/>|
            02|<xsl:value-of select="def"/>|<xsl:value-of select="childtag/asdf"/>|
            03|<xsl:value-of select="def"/>|<xsl:value-of select="childtag/qwe"/>|<xsl:value-of select="childtag/asdf"/>| | 
        </xsl:result-document>
    </xsl:template>
</xsl:stylesheet>

Below is the output generated from above xslt

Below is the text file which contains data from the xslt output

i am stuck with how i can remove the spaces in the file (screen shot mentioned in the above screenshot)

Thank you for showing us your content. Now, what is your question? — Parfait, Jul 04 '16 at 19:18
i want to write the xslt resulted output to the text file into a directory — user2587669, Jul 04 '16 at 19:23
What processor are you using? Saxon or xsltproc receives input and output file paths as arguments at command line. Also any general purpose language (C#, Java, PHP, Python) can save transformed result to file. Be sure to specify [``](http://stackoverflow.com/questions/5908668/use-xsl-to-output-plain-text) — Parfait, Jul 04 '16 at 19:27
Question edited, need help to remove the white spaces in the file which is output by xslt — user2587669, Jul 05 '16 at 19:33
i have used , but still the spaces exists which are shown in the screen shot — user2587669, Jul 05 '16 at 20:17
@user2587669 "*xsltproc you can consider it*" That's not possible. `xsl:result-document` is XSLT 2.0. You will get an error if you try to run that on an XSLT 1.0 processor. — michael.hor257k, Jul 06 '16 at 08:46
michael.hor257k,Parfait thanks for your information. the solution which u provided worked for me — user2587669, Jul 09 '16 at 14:45

michael.hor257k · Accepted Answer · 2016-07-06T08:48:55.097

One way to eliminate the white spaces from your output is to eliminate them from your stylesheet. Instead of:

    <xsl:template match="mainTag">
        <xsl:result-document href="foo.txt" method="text">
            01|<xsl:value-of select="abc"/>|<xsl:value-of select="asd"/>|<xsl:value-of select="childtag/asdf"/>|
            02|<xsl:value-of select="def"/>|<xsl:value-of select="childtag/asdf"/>|
            03|<xsl:value-of select="def"/>|<xsl:value-of select="childtag/qwe"/>|<xsl:value-of select="childtag/asdf"/>| | 
        </xsl:result-document>
    </xsl:template>

use:

<xsl:template match="mainTag">
<xsl:result-document href="foo.txt" method="text">01|<xsl:value-of select="abc"/>|<xsl:value-of select="asd"/>|<xsl:value-of select="childtag/asdf"/>|
02|<xsl:value-of select="def"/>|<xsl:value-of select="childtag/asdf"/>|
03|<xsl:value-of select="def"/>|<xsl:value-of select="childtag/qwe"/>|<xsl:value-of select="childtag/asdf"/>| |</xsl:result-document>
</xsl:template>

Note the lack of indent. This, together with:

<xsl:strip-space elements="*"/>

will produce the required result.

Of course, it's much more convenient to use xsl:text instructions to output literal text, e.g.

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" encoding="UTF-8"/>
<xsl:strip-space elements="*"/>

<xsl:template match="mainTag">
    <xsl:result-document href="foo.txt" method="text">
        <xsl:text>01|</xsl:text>
        <xsl:value-of select="abc"/>
        <xsl:text>|</xsl:text>
        <xsl:value-of select="asd"/>
        <xsl:text>|</xsl:text>
        <xsl:value-of select="childtag/asdf"/>
        <xsl:text>|&#10;02|</xsl:text>
        <xsl:value-of select="def"/>
        <xsl:text>|</xsl:text>
        <xsl:value-of select="childtag/asdf"/>
        <xsl:text>|&#10;03|</xsl:text>
        <xsl:value-of select="def"/>
        <xsl:text>|</xsl:text>
        <xsl:value-of select="childtag/qwe"/>
        <xsl:text>|</xsl:text>
        <xsl:value-of select="childtag/asdf"/>
        <xsl:text>| |</xsl:text>
    </xsl:result-document>
</xsl:template>

</xsl:stylesheet>

Just a tip, sometimes you can use comments in xsl so you can keep format of code (new lines & indents) and it won't be at the output (as is code comment) — vegetable, Mar 14 '23 at 10:47

xslt transformation : create a text file

1 Answers1