How can I temporarily disable the "return value might be undefined" warning?

Question

I want to disable a specific warning (W1035) in my code, since I think that the compiler is wrong about this warning:

function TfrmNagScreen.Run: TOption;
begin
  if ShowModal = mrOk then
    Result := TOption(rdgAction.EditValue)
  else
    Abort
end;

There is no way the result could be undefined, since Abort throws EAbort.

I tried:

{$WARN 1035 Off}: Apparently this only works for some specific errors (see Documentation)
{$W-1035}: Does nothing at all

I know I can switch off the warning globally in the project options, or using {$WARNINGS OFF}, but that is not what is intended here.

Edit: I have QC'ed this now as #89744.

While its true the compiler sometimes gets confused and reports this warning without cause, in this case the compiler is technically correct. Result is not assigned before the conditional and is only assigned on the true branch of the conditional. The fact that the function returns prematurely if the condition is false is irrelevant to the compiler. — Kenneth Cochran, Nov 17 '10 at 18:28
@codeelgance: Quite true, but I think `Abort` is a builtin function and the compiler could recognize the situation. — Jens Mühlenhoff, Nov 17 '10 at 21:21

score 13 · Accepted Answer · answered Nov 17 '10 at 13:10

13

you can't disable this warning globally, but you can use the {$WARN NO_RETVAL OFF} to disable locally the warning.

{$WARN NO_RETVAL OFF}
function TfrmNagScreen.Run: TOption;
begin
  if ShowModal = mrOk then
    Result := TOption(rdgAction.EditValue)
  else
    Abort
end;
{$WARN NO_RETVAL ON}

answered Nov 17 '10 at 13:10

RRUZ

134,889
20
356
483

Where did you get the `NO_RETVAL` from, since it is not in the Embarcadero documentation? – Jens Mühlenhoff Nov 17 '10 at 13:14
1

@Jens, see http://stackoverflow.com/questions/376785/identifiers-for-delphis-warn-compiler-directive/377034#377034 – WileCau Nov 17 '10 at 13:29
Ok, so most (all?) of the warning texts are defined in `DCCStrs.pas`, good to know :) – Jens Mühlenhoff Nov 17 '10 at 13:32
3

Press Ctrl-O-O while editing an unit and then take look at the top of the editor window. :-) – Uli Gerhardt Nov 17 '10 at 15:21

score 9 · Answer 2 · edited May 23 '17 at 12:30

9

I don't have a Delphi compiler available at the moment, but rearranging the code to remove the if..else might make the warning go away:

function TfrmNagScreen.Run: TOption;
begin
  if ShowModal <> mrOk then
    Abort;

  Result := TOption(rdgAction.EditValue);
end;

See also How to disable a warning in Delphi about “return value … might be undefined”?.

edited May 23 '17 at 12:30

Community

1
1

answered Nov 17 '10 at 13:06

WileCau

2,057
1
24
34

+1 That works (for the particular situation) and I had not thought of that, it does not solve the general problem though. – Jens Mühlenhoff Nov 17 '10 at 13:12

score 1 · Answer 3 · answered Nov 17 '10 at 20:28

You can use a neat trick to fool the compiler. Define a library function as so:

procedure Abort(var X);
begin
  SysUtils.Abort;
end;

You can then write your function as:

if ShowModal = mrOk then
  Result := TOption(rdgAction.EditValue)
else
  Abort(Result)

The compiler thinks you've written to Result since it's a var parameter and it stops bleating.

How can I temporarily disable the "return value might be undefined" warning?

3 Answers3

Linked