Batch file, If Statement not working

Question

The following if statement is not running. It just ends the bat file It stops the process. Why is this happening? How do I stop it?

    if "%Choice%"=="si" (GOTO Case2) else (
        if "%Choice%"=="s" (GOTO Case1) else (
            if "%Choice%"=="ti" (GOTO Case4) else (
                if "%Choice%"=="t" (GOTO Case3) else (
                    if "%Choice%"=="i" (GOTO Case5) else (
                        if "%Choice%"=="cp" (GOTO Case6) else (
                            if "%Choice%"=="kp" (GOTO Case7) else (
                                if "%Choice%"=="?" (GOTO CaseHelp) else (
                                    if "%Choice%"=="c" (GOTO Case8) else (
                                        if "%Choice%"=="sl" (GOTO Case9) else (
                                            if "%Choice%"=="sf" (GOTO Case10) else (
                                                if "%Choice%"=="fz" (GOTO Case11) else (
                                                    if "%Choice%"=="dc" (GOTO Case12) else (
                                                        if "%Choice%"=="cm" (GOTO Case12) else (
                                                            if "%Choice%"=="wh" (GOTO Case13) else (
                                                                if "%Choice%"=="vs" (GOTO Case14) else (
                                                                    if "%Choice%"=="it" (GOTO Case15) else (
                                                                        if "%Choice%"=="tm" (GOTO Case16) else (
                                                                            if "%Choice%"=="d" (GOTO Case17) else (
                                                                                if "%Choice%"=="ed" (GOTO Case18) else  (
                                                                                    if "%Choice%"=="be" (GOTO Case19) else (
                                                                                        if "%Choice%"=="me" (GOTO Case20) else (
                                                                                            if "%Choice%"=="ap" (GOTO Case21) else (
                                                                                                if "%Choice%"=="pc" (GOTO Case22) else (
                                                                                                    if "%Choice%"=="sc" (GOTO Case23) else (
                                                                                                        if "%Choice%"=="c" (GOTO Case24) else (
                                                                                                            if "%Choice%"=="ll" (GOTO Case25) else (
                                                                                                                if "%Choice%"=="ij" (GOTO Case26) else (
                                                                                                                    GOTO CaseError)
                                                                                                )
                                                                                            )
                                                                                        )
                                                                                    )
                                                                                )
                                                                            )
                                                                        )
                                                                    )
                                                                )
                                                            )
                                                        )
                                                    )
                                                )
                                            )
                                        )
                                    )
                                )
                            )
                        )
                    )
                )
            )
        )

Also, is there an alternative of using an if statement as this method is uite time consuming.

Any reason for the use of if else with all of the extensive indenting? as each if statement is followed by a GOTO then the else part is not required - you can have a list of if statements followed by a GOTO CaseError without indenting which will make it easier to read. If this section of code does not have an error - do you have a problem in the remainder of the batch file. Use basic debugging techniques - remove all lines except the first if & the GOTO CaseError & see if that works - then add each line in turn to see where it stops working. — PaulF, Sep 30 '17 at 18:43
As for an alternative to multiple if statements - instead of using Case1, Case2 as labels you could use Cases & Casesi as labels & use the technique described here : https://stackoverflow.com/questions/18423443/switch-statement-equivalent-in-windows-batch-file - I cant remember of the top of my head if ? is valid in a label (I don't think so) - so you may need to make a special check for that first. — PaulF, Sep 30 '17 at 18:49
You haven't provided the part of your code which `Set`'s the `%choice%` variable either, so it's impossible for us to know what it's expanded string value is. — Compo, Sep 30 '17 at 18:50
Thanks, @Compo and @PaulF for your comments. The variable choice, is `set /p Choice= Which Service? `. I'll try your debugging @PaulF... — Sank6, Sep 30 '17 at 19:04
Debugging batch files can be a real pain - one of your best tools is the ECHO statement to see what is happening & which lines you actually get to. Use Echo "%Choice%" directly after the set - replace all of the GOTO's with ECHO - put an ECHO as the first line after your labels (after you put the GOTO's back). Your code seems to have extra indenting - is that because if is already in an if/else statement - if so are you sur your are even getting to your if statement? — PaulF, Sep 30 '17 at 19:20

dbenham · Accepted Answer · 2017-10-01T12:22:26.260

Well, I see 28 opening (, but only 24 closing ), so it can't possibly work.

You don't show your complete relevant code, we can't see if you have all the required labels.

PaulF has a good point in his comment, since each IF does a GOTO, you don't need any ELSE statements.

if "%Choice%"=="si" GOTO Case2
if "%Choice%"=="s"  GOTO Case1
if "%Choice%"=="ti" GOTO Case4
etc...
if "%Choice%"=="ij" GOTO Case26
goto CaseError

But let's suppose that you are not doing GOTO with each IF, but rather something else. There is no need to do a lot of indents, and you don't need so many parens. Batch does not formally have an ElseIf, but it functionally works just as well if you use ELSE IF. Look how I arrange the parens and indents - it is much easier to read and follow the code.

if "%Choice%"=="xxx" (
  do something
) else if "%Choice%"=="yyy" (
  do something else
) else if "%Choice%"=="zzz" (
  do something different
) else (
  everything else gets to here
)

Since you are performing GOTOs, there is another option. Incorporate the %Choice% value in the :label, and then you don't need any IF statement, other than to verify that the choice is valid, and take special action if it isn't.

Opion 1: Define the list of valid entries, and use find/replace to test if the choice is amongst the valid options. This is best done with delayed expansion. Note the leading and trailing space in the options list is important in this technique.

setlocal enableDelayedExpansion
set "options= si s ti t i cp kp ? c sl sf fz dc cm wh vs it tm d ed be me ap pc sc c ll ij "
set "choice="
set /p "choice=Enter your choice: "
if "!options: %choice% =!" neq "!options!" goto case_%choice%
goto case_error

:case_si
rem do something
exit /b

:case_s
rem do something else
exit /b

etc...

Option 2: Use FINDSTR to probe the batch file itself to verify the label exists. Here I am using a simplified search that will not handle all possible arrangements of valid labels. But it should be fine as long as you don't get creative with how you create your labels.

set "choice="
set /p "choice=Enter your choice: "
findstr /i /r /c:"^:case_%choice%$" /c:"^:case_%choice% " "%~f0" >nul 2>nul && goto :case_%choice%
goto :case_error

:Case_si
rem do something
exit /b

:Case_s
rem do something else
exit /b

etc...

I tried your second option as I liked it, but it didn't go to the `case_%choice%`. Any reason why it just goes straight to the error without running that line? — Sank6, Oct 01 '17 at 09:03
Yes, there is a very good (well, bad) reason - I was sloppy, and had two bugs. I forgot the `/R` regular expression option, and I had the wrong variable name. All fixed now — dbenham, Oct 01 '17 at 12:17
Also for your first method, the line `goto case_error` never actually runs as it attempts to `goto case_%choice%` and returns an error if it cannot go there. It never actually goes to the error case. — Sank6, Oct 01 '17 at 14:57
@Sank6 - I tested option 1, and it works fine for me. Make sure your `:case_error` label actually exists. The technique can fail if the user input includes `!` or `"` or `=`, but other than that, it should work fine. Have you retested Option 2? It now works fine for me. — dbenham, Oct 01 '17 at 16:45
@Sank6 - Also, option 2 expects the label to be at the very beginning of the line (no leading spaces). The FINDSTR queries can easily be modified to allow for leading spaces. — dbenham, Oct 02 '17 at 12:54

Mofi · Answer 2 · 2017-10-01T10:04:50.517

I suggest to use the command CHOICE for this large selection between 28 options:

@echo off
:Menu
cls
echo 1 ... option 1
echo 2 ... option 2
echo       and so on
echo 9 ... option 9
echo a ... option 10
echo       and so on
echo r     option 27
echo 0 ... help
echo/
%SystemRoot%\System32\choice.exe /C 123456789abcdefghijklmnopqr0 /N /M "Your choice: "
goto Case%ERRORLEVEL%

:Case1
echo Option 1
goto :EOF

:Case2
echo Option 2
goto :EOF

rem And so on

:Case28
cls
echo Help
echo/
pause
goto :Menu

Command CHOICE does not allow any invalid input. It waits with the used options until the user presses any key as specified after parameter /C and assigns to ERRORLEVEL the number according to index of the appropriate key/character in the list, i.e. 1 for first 1, 2 for second 2 and 28 for last key/character 0. Run in a command prompt window choice /? for help on this command.

goto Case%ERRORLEVEL% is not working if the entire menu code is within a command block starting with ( and ending with matching ) because variable reference %ERRORLEVEL% is replaced already by current value of environment variable ERRORLEVEL before the command left to ( is executed at all.

Delayed expansion must be enabled in this case and goto Case!ERRORLEVEL! must be used to get the GOTO working within a command block. Run in a command prompt set /? and read the hep output on several window pages for details about delayed expansion as well as setlocal /? used to enable delayed expansion and endlocal /? to restore previous command environment.

An alternate solution for the menu within a command block without using delayed environment variable expansion is replacing the command line goto Case%ERRORLEVEL% by

for /L %%X in (28,-1,1) do if errorlevel %%X goto Case%%X

See the Microsoft support article about Testing for a Specific Error Level in Batch Files why the decrementing FOR loop with the if errorlevel X condition executing goto CaseX works within a command block without usage of delayed expansion.

Aacini · Answer 3 · 2017-10-01T00:45:24.783

I think this is the simplest way to solve this problem:

@echo off
setlocal

set /p "Choice= Which Service? "
call :Case-%choice% 2> NUL
if errorlevel 1 goto CaseError
goto :EOF

:Case-si
echo You select "si" service
exit /B

:Case-s
echo You select "s" service
exit /B

:Case-etc
echo You select "etc" service
exit /B

:CaseError
echo Error: invalid service...
goto :EOF

When a call with a non-defined label is executed, the system automatically set ERRORLEVEL to one and continue to the next line, so you just need an if to detect such an error...

Using this method you don't need to check for each one of the options, just include the desired code below each one of the proper :Case-serviceNameHere labels and that is it!

Sure, if the OP can modify the logic to use CALL instead of GOTO, then this is definitely easier. And CALL is generally preferable to GOTO anyway. But there are times when GOTO is preferred, and GOTO :NonExistentLabel will terminate the script with a fatal error. I realize you know this, but it needs to be mentioned. — dbenham, Oct 01 '17 at 05:00

Batch file, If Statement not working

3 Answers3