Maybe coalescing operator

Question

I'm wondering how I could go about defining an operator / if an operator already exists in Haskell that lets pick the first Maybe type that isn't Nothing, and if all if them are nothing, it returns some default. Basically something like this:

let x = a ?? b ?? c ?? 1

where (??) is the operator and a, b, c are all Maybe types. I'd expect this code to return the first value that is Just or 1 if all of a, b, c are Nothing.

I'm basically looking to replicate the same functionality as the null coalescing operator you'd find in C# or other languages.

This question shows how to do it in F# (Null Coalescing Operator in F#?), and it's quite hacky. Is there a way to do it cleanly in Haskell, and if not, what's the closest you can get to it?

[Hoogle](https://www.haskell.org/hoogle/?hoogle=Maybe+a+-%3E+Maybe+a+-%3E+Maybe+a) is a great tool for finding this kind of thing. — AJF, Nov 19 '17 at 00:00

Alec · Accepted Answer · 2017-11-18T23:27:42.550

12

Haskeller's would generally use (<|>) :: Maybe a -> Maybe a -> Maybe a for this sort of thing. Assuming a, b, c :: Maybe Int, you have x :: Maybe Int

let x = a <|> b <|> c <|> Just 1

Of course, that isn't really what you asked for. If you want, you could define it though!

-- You expect `a ?? b ?? c ?? 1` to parse as `a ?? (b ?? (c ?? 1))`
infixr 3 ??

-- (Someone is going to point out that `(??) = flip fromMaybe`, so I am first)
(??) :: Maybe a -> a -> a
Just x ?? _ = x
Nothing ?? y = y

Then, you get precisely the behaviour you expect. Assuming a, b, c :: Maybe Int, you have x :: Int:

let x = a ?? b ?? c ?? 1

edited Nov 18 '17 at 23:27

answered Nov 18 '17 at 23:23

Alec

31,829
7
67
114

your answer is better. – Jason Hu Nov 18 '17 at 23:27
You can use `1` with `<|>` if you have a handy `instance Num a => Num (Maybe a)` lying around. – Rein Henrichs Nov 19 '17 at 01:29
We can also use `asum` from `Data.Foldable` to combine a list of maybes using `<|>`. – danidiaz Nov 19 '17 at 08:52

Jason Hu · Answer 2 · 2017-11-19T19:53:03.237

3

Do you mind writing it differently?

safeHead [] d = d
safeHead (h:_) _ = h

then

let x = safeHead (catMaybes [a, b, c]) 1

shall do what you want.

If you want to do it in that way, it's doable, but two operators are required.

a@(Just _) ?? _ = a
_ ?? b = b

(Just e) ?: _ = e
_ ?: d = d

defines the two operators you need, and they work:

Prelude> let a = Nothing
Prelude> let b = Nothing
Prelude> let c = Just 3
Prelude> a ?? b ?? c ?: 10
3
Prelude> a ?? b ?? Nothing ?: 10
10

edited Nov 19 '17 at 19:53

answered Nov 18 '17 at 23:18

Jason Hu

6,239
1
20
41

This works, but I think you're right in that I should be clear that I want it done specifically in the way I specified above. I'll edit it and add an example I saw in F# too. – m0meni Nov 18 '17 at 23:20
@m0meni i don't program F# i am sorry. but i can show you how to do it with operators in haskell(but two operators). – Jason Hu Nov 18 '17 at 23:22

score 1 · Answer 3 · answered Nov 19 '17 at 16:02

Just for some practicing purposes this job can also be expressed by the Monoid class type First which is a Maybe monoid returning the leftmost non-Nothing value.

import Data.Monoid
import Data.Maybe (fromJust)

infixr 3 ??

(??) :: Maybe a -> a -> a
x ?? y = fromJust . getFirst $ First x <> First (Just y)

*Main> Nothing ?? Nothing ?? 1
1
*Main> Nothing ?? Just 3 ?? 1
3
*Main> Just 7 ?? Just 3 ?? 1
7

Maybe coalescing operator

3 Answers3