Concatenate fields of a dynamic structure

Question

How do we concatenate fields of a dynamic work area? The idea is in the below code:

LOOP AT lt_final INTO DATA(ls_final).
  CONCATENATE ls_final-field1
              ls_final-field2
              ls_final-field3
              ls_final-field4
              ls_final-field5
         INTO ls_attachment SEPARATED BY lc_tab.   "lc_tab is horizontal tab

  APPEND ls_attachment TO lt_attachment.
  CLEAR: ls_attachment.
ENDLOOP.

(This code will be used for sending email attachment.) Now, my problem is, the internal table in the above code is a dynamic internal table, therefore I am not sure how many fields will be there and the field names as well.

How do I concatenate the fields? Any idea, please help..

LOOP AT <dynamic_table> INTO DATA(ls_final).
  CONCATENATE ls_final-(?)
              ls_final-(?)
              ls_final-(?)
              ls_final-(?)
              ls_final-(?) 
              "or more fields insert here depending on dynamic table
         INTO ls_attachment SEPARATED BY lc_tab.   "lc_tab is horizontal tab

  APPEND ls_attachment TO lt_attachment.
  CLEAR: ls_attachment.
ENDLOOP.

score 5 · Accepted Answer · edited Feb 24 '18 at 18:34

FIELD-SYMBOLS: <lv_field> TYPE ANY.

LOOP AT lt_final
     ASSIGNING FIELD-SYMBOL(<ls_final>).
  DO.
    ASSIGN COMPONENT sy-index
           OF STRUCTURE <ls_final>
           TO <lv_field>.
    IF sy-subrc EQ 0.
      IF sy-index EQ 1.
        ls_attachment = <lv_field>.
      ELSE.
        ls_attachment = ls_attachment && lc_tab && <lv_field>.
      ENDIF.
    ELSE.
      EXIT.
    ENDIF.
  ENDDO.
ENDLOOP.

I hope it is self explaining, but: You can use the system variable (sy-index), it is incremented automatically by SAP. In the first step, just copy the value, there is nothing to concatenate yet (otherwise there will be an unnecessary lc_tab at the beginning of the string).

Thanks @JozsefSzikszai ! This solved my problem and easy to understand. — Czarinaaaaa29, Dec 29 '17 at 21:11

score 3 · Answer 2 · answered Dec 29 '17 at 02:15

3

Just read your structure by index.

data :
     lv_attachment type string.
     lv_index type i value 1.
field-symbols:
             <lv_value> type any.

while 1 = 1.
    assign component lv_index of structure ls_final to <lv_value>.
    if sy-subrc <> 0.
      exit.
    endif.
    concatenate lv_attachment <lv_value> into lv_attachment separated by lc_tab.
    lv_index = lv_index + 1.
endwhile.

Hope it helps.

answered Dec 29 '17 at 02:15

Haojie

5,665
1
15
14

2

Nice answer, although I prefer 'DO. ENDO.' with 'sy-index' due to its brevity. – Jagger Dec 29 '17 at 12:56
Yup @Allen ! This helped a lot, thanks. But I prefer the DO ENDDO approach below. Much easier for me to understand. Thanks a lot! – Czarinaaaaa29 Dec 29 '17 at 21:10

score 2 · Answer 3 · answered Mar 25 '18 at 14:54

You can use CL_ABAP_CONTAINER_UTILITIES class for that task, method FILL_CONTAINER_C.

Here is the sample of populating dynamic table and concatenating its fields into container field:

PARAMETERS: p_tab TYPE string.

FIELD-SYMBOLS: <fs_tab> TYPE STANDARD TABLE.

DATA tab TYPE REF TO data.
CREATE DATA tab TYPE TABLE OF (p_tab).
ASSIGN tab->* TO <fs_tab>.

SELECT * UP TO 100 ROWS
  INTO TABLE <fs_tab>
  FROM (p_tab).

LOOP AT <fs_tab> ASSIGNING FIELD-SYMBOL(<fs_line>).

CALL METHOD CL_ABAP_CONTAINER_UTILITIES=>FILL_CONTAINER_C
  EXPORTING
    IM_VALUE                = <fs_line>
  IMPORTING
    EX_CONTAINER            = DATA(container)
  EXCEPTIONS
    ILLEGAL_PARAMETER_TYPE = 1
    others                 = 2.

CONDENSE container.

" do smth

ENDLOOP.

Concatenate fields of a dynamic structure

3 Answers3