How to interleave two given vectors in APL

Question

I'm trying to solve a problem using APL, for which I have two vectors v1 and v2, with relative length of at most +1, depending on the input. That means that ((≢v1)-(≢v2))∊¯1 0 1.

What would be the best way to interleave said vectors, so to create a third vector v3 such that v3=v1[0],v2[0],v1[1],v2[1],...?

(If it's relevant, I'm using Dyalog APL version 16.0)

I guess you could make this question a bit more general, by removing the relative length part, given all answers so far don't consider it (and support any difference) or apply only for equal length — Uriel, Jan 14 '18 at 16:21

Lobachevsky · Accepted Answer · 2018-01-12T11:07:01.467

10

This should work in just about every APL.

(v0,v1)[⍋(⍳⍴v0),⍳⍴v1]

If you want to worry about either v0 or v1 being scalars, then

(v0,v1)[⍋(⍳⍴,v0),⍳⍴,v1]

edited Jan 12 '18 at 11:07

answered Jan 12 '18 at 11:01

Lobachevsky

1,222
9
17

This is about as classic as it gets. Very useful idiom. – Lobachevsky Jan 12 '18 at 16:25

score 7 · Answer 2 · answered Jan 11 '18 at 13:42

If you don't mind getting a prototype fill element when the vectors have unequal length, then

Interleave←{,⍉↑⍵}

will do. Try it online!

Otherwise, you can interleave the matching parts, and then append the missing element(s — it works for length-differences greater than one too):

Interleave←{
    lengths←⌊/≢¨⍵
    main←,⍉↑lengths↑¨⍵
    tail←⊃,/lengths↓¨⍵
    main,tail
}

Try it online!

Uriel · Answer 3 · 2018-01-11T14:03:16.573

Using a Dyalog dfn:

zip ← {
    mix ← ,⍉↑ ⍺ ⍵
    mask ← ,⍉↑ 1⊣¨¨ ⍺ ⍵
    mask / mix
}

The idea here is to mix both arguments, then transpose the result and finally flatten it (mix).

Then, we apply the same on an array of 1s, corresponding to the length of the given arrays (mask), and use it as a mask, to filter the prototypes added by the mix primitive.

Note that this allows also for zipping arrays with a difference of length greater than one element.

Try it online!

score 5 · Answer 4 · edited Jan 15 '18 at 07:47

5

As I do not know Dyalog APL, I answer in the old ISO APL from the 1970's years:
(v1,v2)[⍋((0.5×(⍴v1)<⍴v2)+⍳⍴v1),((0.5×(⍴v2)<⍴v1)+⍳⍴v2]

The first element will be the one of the longuest vector, if they have the same length, the first element is the first element of v1.

edited Jan 15 '18 at 07:47

Adám

6,573
20
37

answered Jan 11 '18 at 20:58

GilVib

51
2

For how to type APL symbols, have a look [here](https://www.dyalog.com/apl-font-keyboard.htm) and [here](https://abrudz.github.io/lb/apl) and [here](https://github.com/abrudz/Kbd). – Adám Jan 14 '18 at 17:39

score 4 · Answer 5 · answered Jan 12 '18 at 09:49

4

Here's how I would solve the original question in APL2:

LEN←∊⌊/⍴¨V1 V2 
V3←∊((LEN↑V1),¨LEN↑V2),LEN↓¨V1 V2

answered Jan 12 '18 at 09:49

mappo

444
2
9

Jimmy Gauvin · Answer 6 · 2019-09-05T21:49:43.027

With vectors of same length use the inner product:

 1 2 3,.,40 50 60

┌──────────────┐
│1 40 2 50 3 60│
└──────────────┘

Building on top of that begets this dfn :

{r←(⍴⍺)⌊⍴⍵⋄(∊(r⍴⍺),.,r⍴⍵),(r↓⍺),r↓⍵}

alternatively, we can laminate (keeping the same overall logic):

{r←(⍴⍺)⌊⍴⍵⋄(,(r⍴⍺),⍪r⍴⍵),(r↓⍺),r↓⍵}

How to interleave two given vectors in APL

6 Answers6