How to get hashes out of arrays in Perl?

Question

I want to write a little "DBQuery" function in perl so I can have one-liners which send an SQL statement and receive back and an array of hashes, i.e. a recordset. However, I'm running into an issue with Perl syntax (and probably some odd pointer/reference issue) which is preventing me from packing out the information from the hash that I'm getting from the database. The sample code below demonstrates the issue.

I can get the data "Jim" out of a hash inside an array with this syntax:

print $records[$index]{'firstName'}

returns "Jim"

but if I copy the hash record in the array to its own hash variable first, then I strangely can't access the data anymore in that hash:


    %row = $records[$index];
    $row{'firstName'};

returns "" (blank)

Here is the full sample code showing the problem. Any help is appreciated:


my @records = (
   {'id' => 1, 'firstName' => 'Jim'},
   {'id' => 2, 'firstName' => 'Joe'}
);
my @records2 = ();

$numberOfRecords = scalar(@records);
print "number of records: " . $numberOfRecords . "\n";
for(my $index=0; $index < $numberOfRecords; $index++) {

   #works
   print 'you can print the records like this: ' . $records[$index]{'firstName'} . "\n";

   #does NOT work
   %row = $records[$index];
   print 'but not like this: ' . $row{'firstName'} . "\n";

}

score 23 · Accepted Answer · answered Sep 09 '08 at 04:03

23

The nested data structure contains a hash reference, not a hash.

# Will work (the -> dereferences the reference)
$row = $records[$index];
print "This will work: ", $row->{firstName}, "\n";

# This will also work, by promoting the hash reference into a hash
%row = %{ $records[$index] };
print "This will work: ", $row{firstName}, "\n";

If you're ever presented with a deep Perl data structure, you may profit from printing it using Data::Dumper to print it into human-readable (and Perl-parsable) form.

answered Sep 09 '08 at 04:03

Commodore Jaeger

32,280
4
54
44

If you ever need to explictly dereference a reference then %{$row} will work, which can be useful sometimes to ensure you're passing the right thing to the right sort of thing. – Free Wildebeest Sep 14 '08 at 23:51
my $h_ref = $arrayOfValidImages[$i]; (Is a valid array of hash refs and valid index) my %image_info = %{$h_ref}; (This very next line gives an error: "Can't use an undefined value as a HASH reference at ". Any idea? – Shravya Boggarapu Oct 20 '16 at 11:00

score 5 · Answer 2 · answered Sep 09 '08 at 04:08

5

The array of hashes doesn't actually contain hashes, but rather an references to a hash. This line:

%row = $records[$index];

assigns %row with one entry. The key is the scalar:

   {'id' => 1, 'firstName' => 'Jim'},

Which is a reference to the hash, while the value is blank.

What you really want to do is this:

$row = $records[$index];
$row->{'firstName'};

or else:

$row = %{$records[$index];}
$row{'firstName'};

answered Sep 09 '08 at 04:08

Nathan Fellman

122,701
101
260
319

1

That last bit of code makes no sense. It should be something like: %row=%{$records[$index]}; print $row{'firstName'}; – Peter Stuifzand Sep 16 '08 at 14:11

score 4 · Answer 3 · answered Sep 09 '08 at 06:48

Others have commented on hashes vs hashrefs. One other thing that I feel should be mentioned is your DBQuery function - it seems you're trying to do something that's already built into the DBI? If I understand your question correctly, you're trying to replicate something like selectall_arrayref:

This utility method combines "prepare", "execute" and "fetchall_arrayref" into a single call. It returns a reference to an array containing a reference to an array (or hash, see below) for each row of data fetched.

score 3 · Answer 4 · answered Sep 09 '08 at 23:33

To add to the lovely answers above, let me add that you should always, always, always (yes, three "always"es) use "use warnings" at the top of your code. If you had done so, you would have gotten the warning "Reference found where even-sized list expected at -e line 1."

score 1 · Answer 5 · answered Sep 09 '08 at 04:05

what you actually have in your array is a hashref, not a hash. If you don't understand this concept, its probably worth reading the perlref documentation.

to get the hash you need to do

my %hash = %{@records[$index]};

Eg.

my @records = (
     {'id' => 1, 'firstName' => 'Jim'}, 
     {'id' => 2, 'firstName' => 'Joe'}
  );

  my %hash = %{$records[1]};

  print $hash{id}."\n";

Although. I'm not sure why you would want to do this, unless its for academic purposes. Otherwise, I'd recommend either fetchall_hashref/fetchall_arrayref in the DBI module or using something like Class::DBI.

@records[$index] better written as $records[$index] – Francisco Zarabozo Jun 03 '14 at 05:40 — Francisco Zarabozo, Jun 03 '14 at 05:40

score 0 · Answer 6 · answered Sep 16 '08 at 09:22

0

Also note a good perl idiom to use is

for my $rowHR ( @records ) {
   my %row = %$rowHR; 
   #or whatever...
}

to iterate through the list.

answered Sep 16 '08 at 09:22

jonfm

249
2
4

How to get hashes out of arrays in Perl?

6 Answers6