Batch How to extract second last folder of few Paths and then use them

Question

The following code is creating shortcuts to Paths listed in List.txt textfile (like C:/folder1/folder2/folder3/folder4), and saves all shortcuts to path specified in set SAVETO. How to extract each Folder3 (second last folder name of each row in List.txt, to use it then in %SAVETO% paths)?

<...>
SET "SAVETO=%userprofile%\desktop"
for /f "usebackq delims=" %%G IN ("List.txt") DO (
    call :createLink "%%~nG" "%%G"
)
goto :eof

:createLink
set SCRIPT="%TEMP%\%RANDOM%-%RANDOM%-%RANDOM%-%RANDOM%.vbs"
echo Set oWS = WScript.CreateObject("WScript.Shell") >> %SCRIPT%
echo sLinkFile = "%SAVETO%\%~1.lnk" >> %SCRIPT%
echo Set oLink = oWS.CreateShortcut(sLinkFile) >> %SCRIPT%
echo oLink.TargetPath = "%~2" >> %SCRIPT%
<...>

After receiving second last folder, the shortcut must be saved to:

D:/custompath/%Folder3-second last from row in List.txt%/

UPDATE: For example, this code is almost what I need, it extracts folder3 name, but I can't apply this to my code. And also it's not necessary for me to check equ "\"

setlocal EnableDelayedExpansion
set "var=C:\folder 1\folder 2\folder 3\folder 4\"
if "%var:~-1%" equ "\" set var=%var:~0,-1%
set var=%var:\=" "%
for %%a in ("%var%") do (
   set lastButOne=!lastFolder!
   set lastFolder=%%~a
)
echo Last but one: %lastButOne%

And when code returning second last folder name of current line from List.txt I want to use its name in save path C:/path/*Second Last Folder Name*/Shortcut. And I need to do this for each line separately. So if first line of List.txt is path C:/a/bbb/c then shortcut to this path must be saved to c:/custom_path/bbb/shortcut_name, for C:/ab/cd/efff/g it must be saved to c:/custom_path/efff/shortcut_name.

Answer 1

UPDATE I've altered the code to get the parent directory name correctly.

This is an example of a nested FOR loop (referred to in the comments) that you could use to extract the parent of the directory that comes from each line of input.

@SETLOCAL ENABLEDELAYEDEXPANSION
FOR /F "delims=" %%G IN (List.txt) DO (
    SET "PARENT=%%~dpG"
    REM  Strip off the trailing backslash. ~p leaves the backslash at the end.
    SET "PARENT=!PARENT:~0,-1!"
    FOR /F "delims=" %%P IN ("!PARENT!") DO (
        CALL :createLink "%%~nxG" "%%~nxP" "%%~dpP"
    )
)
EXIT /B

:createLink will be invoked with the name of the "leaf" directory as the first parameter, the name (only—no path) of the parent dir of that directory, and the path to that directory's parent as the third. I realize this is not precisely what your code wants, but as I don't really understand what you want to accomplish (not that it's wrong—the way you're using the data just seems unusual to me), at least two of the three pieces of information here (though I don't know which two) seem like what you're asking for.

Though goto :eof generally works (unless you define :eof somewhere other than the end of the file), I prefer EXIT /B since it's straightforward and does exactly what you want.

For testing, I used this as List.txt

C:/folder1/folder2/folder3/folder4
C:/folder1/folder12/folder113/folder1114/folder/folder11115
C:\folderA\folderB\folderC\folderD

If I add some debugging to the above code:

@SETLOCAL ENABLEDELAYEDEXPANSION
@ECHO OFF
FOR /F "delims=" %%G IN (List.txt) DO (
    @ECHO G: %%~G
    SET "PARENT=%%~dpG"
    SET "PARENT=!PARENT:~0,-1!"
    FOR /F "delims=" %%P IN ("!PARENT!") DO (
        @ECHO P: %%~P
        CALL :createLink "%%~nxG" "%%~nxP" "%%~dpP"
    )
)
EXIT /B

:createLink
@ECHO :createLink
@ECHO   Arg 1: %~1
@ECHO   Arg 2: %~2
@ECHO   Arg 3: %~3
EXIT /B

Then the output I get when I run the script is:

G: C:/folder1/folder2/folder3/folder4
P: C:\folder1\folder2\folder3
:createLink
  Arg 1: folder4
  Arg 2: folder3
  Arg 3: C:\folder1\folder2\
G: C:/folder1/folder12/folder113/folder1114/folder/folder11115
P: C:\folder1\folder12\folder113\folder1114\folder
:createLink
  Arg 1: folder11115
  Arg 2: folder
  Arg 3: C:\folder1\folder12\folder113\folder1114\
G: C:\folderA\folderB\folderC\folderD
P: C:\folderA\folderB\folderC
:createLink
  Arg 1: folderD
  Arg 2: folderC
  Arg 3: C:\folderA\folderB\