Master File is open even after execution completed

Question

I have a vba code (not mine copied from another site) which seperates data from master file into multiple files based on specific column ,now after the data has been separated into multiple files the code execution has been completed , but the master file is open at the end which is not good , tried to various ways to apply code for save the master file and close the master file but not working , I have no idea about vba coding,the master file is FE_JUL.xlsx

Sub ExportDatabaseToSeparateFiles()
     'Export is based on the value in the KeyCol
    Dim myWb As Workbook
    Dim myCell As Range
    Dim mySht As Worksheet
    Dim myName As String
    Dim myArea As Range
    Dim myShtName As String
    Dim KeyCol As String
    Dim myField As Integer

    Application.ScreenUpdating = False
    Workbooks.Open Filename:="C:\FInal Estimate\Excel\2019\temp\FE_JUL.xlsx"
    Set myWb = Application.Workbooks("FE_JUL.xlsx")
    myWb.Activate
    myShtName = ActiveSheet.Name
    KeyCol = "A"
    Set myArea = Intersect(ActiveSheet.UsedRange, Range(KeyCol & "1").EntireColumn).Cells
    Set myArea = myArea.Offset(1, 0).Resize(myArea.Rows.Count - 1, 1)
    myField = myArea.Column - myArea.CurrentRegion.Cells(1).Column + 1
    For Each myCell In myArea
        On Error GoTo NoSheet
        myName = Worksheets(myCell.Value).Name
        GoTo SheetExists:

NoSheet:
        Set mySht = Worksheets.Add(Before:=Worksheets(1))
        mySht.Name = myCell.Value
        With myCell.CurrentRegion
            .AutoFilter Field:=myField, Criteria1:=myCell.Value
            .SpecialCells(xlCellTypeVisible).Copy _
                    mySht.Range("A1")
            mySht.Cells.EntireColumn.AutoFit
            .AutoFilter
        End With
        Resume

SheetExists:
    Next myCell
    For Each mySht In ActiveWorkbook.Worksheets
        If mySht.Name = myShtName Then
            Exit Sub
        Else
            mySht.Move
            ActiveWorkbook.SaveAs "C:\FInal Estimate\Excel\2019\temp\temp\" & ActiveSheet.Name & ".xlsx"
            ActiveWorkbook.Close
        End If
    Next mySht

    myWb.Save
    myWb.Close

End Sub

Answer 1

The main reason why your code does not work is because there is an Exit Sub which exits the sub so myWb.Close is never reached. You must replace it with Exit For.

Nevertheless I recommend to refine the code as follows to make it more solide and reliable. You might benefit from reading How to avoid using Select in Excel VBA. Also using Goto is a bad practice see below for a solution without it.

Option Explicit

Sub ExportDatabaseToSeparateFiles()
    'Export is based on the value in the KeyCol
    Application.ScreenUpdating = False

    Dim myWb As Workbook
    Set myWb = Workbooks.Open(Filename:="C:\FInal Estimate\Excel\2019\temp\FE_JUL.xlsx")

    Dim MySht As Worksheet
    Set MySht = myWb.ActiveSheet

    Const KeyCol As String = "A"

    Dim myArea As Range
    Set myArea = Intersect(MySht.UsedRange, MySht.Range(KeyCol & "1").EntireColumn).Cells
    Set myArea = myArea.Offset(1, 0).Resize(myArea.Rows.Count - 1, 1)

    Dim myField As Long
    myField = myArea.Column - myArea.CurrentRegion.Cells(1).Column + 1

    Dim myCell As Range
    For Each myCell In myArea
        If Not WorksheetExists(myCell.Value, myWb) Then
            Dim AddedSht As Worksheet
            Set AddedSht = myWb.Worksheets.Add(Before:=myWb.Worksheets(1))
            AddedSht.Name = myCell.Value
            With myCell.CurrentRegion
                .AutoFilter Field:=myField, Criteria1:=myCell.Value
                .SpecialCells(xlCellTypeVisible).Copy AddedSht.Range("A1")
                AddedSht.Cells.EntireColumn.AutoFit
                .AutoFilter
            End With
        End If
    Next myCell

    Dim ws As Worksheet
    For Each ws In myWb.Worksheets
        If ws.Name = MySht.Name Then
            Exit For
        Else
            ws.Move
            ActiveWorkbook.SaveAs "C:\FInal Estimate\Excel\2019\temp\temp\" & ActiveSheet.Name & ".xlsx"
            ActiveWorkbook.Close SaveChanges:=False
        End If
    Next ws

    Application.ScreenUpdating = True

    myWb.Save
    myWb.Close SaveChanges:=False
End Sub


Public Function WorksheetExists(WorksheetName As String, Optional InWorkbook As Workbook) As Boolean
    If InWorkbook Is Nothing Then Set InWorkbook = ThisWorkbook

    Dim ws As Worksheet
    On Error Resume Next
    Set ws = InWorkbook.Worksheets(WorksheetName)
    On Error GoTo 0

    WorksheetExists = Not ws Is Nothing
End Function