Cannot bring a process to the front

Question

I'm currently developing software in VB.NET (using Visual Studio 2019).

I need to bring a process to the front. I'm using this code:

Private Sub BringInternet_Click(sender As Object, e As EventArgs) Handles BringInternet.Click
    Dim mngcls As ManagementClass = New ManagementClass("Win32_Process")
    Do
        For Each instance As ManagementObject In mngcls.GetInstances()
            If instance("Name").ToString = "msedge.exe" Then
                Dim ID As Integer = instance("ProcessId")
                MsgBox(ID)

                AppActivate(ID)
                Exit Do
            End If
        Next
    Loop While False
End Sub

Sometimes it's working but most of the time it doesn't work. I've already done some research about this but I found nothing about this bug.

First of all, what's the point of the `Do...While` loop? It will only run once anyway. — 41686d6564 stands w. Palestine, Aug 18 '20 at 14:52
To exit when the process is found. Else I have an error because I try to call the same process more than once. — Jason Madi, Aug 18 '20 at 14:54
You could remove the `Do...While` and just `Exit For` on the `For Each` loop instead. — Craig, Aug 18 '20 at 14:55
Again, your `Do...While` loop will only run once (because of `Loop While False`). You should either change the condition (if you really need the loop; but I don't think you need it) or you should get rid of it and use `Exit For` instead of `Exit Do`. — 41686d6564 stands w. Palestine, Aug 18 '20 at 14:55
I've been remove my loop and replace by Exit For but it's the same. — Jason Madi, Aug 18 '20 at 14:59
Surprising it works at all, Edge is a UWP app. Use `Process.Start("microsoft-edge:")` instead. [Backgrounder](https://stackoverflow.com/a/41906116/17034) — Hans Passant, Aug 18 '20 at 15:37
@HansPassant Not the new Chromium-based version though: https://www.askvg.com/microsoft-to-retire-internet-explorer-and-legacy-microsoft-edge-web-browsers-soon. — 41686d6564 stands w. Palestine, Aug 18 '20 at 15:52
@Hans It does indeed (I'm not sure why) but is it a UWP app? It's located under `Program Files (x86)` and works well with `ShowWindow()` and `SetForegroundWindow()`. That's a little odd. It's always great to get your insights though, so please let me know if there's something I'm missing. — 41686d6564 stands w. Palestine, Aug 18 '20 at 16:07

41686d6564 stands w. Palestine · Accepted Answer · 2020-08-18T16:10:21.713

It's been a while since I used AppActivate (back in the VB6 days). Apparently, it's simply a wrapper around the SetForegroundWindow() Win32 function, meaning that it only brings the window to front (if it's already in a restored state) but it doesn't restore it if minimized.

In order to restore the window and then bring it to front, you need to call ShowWindow() first and then SetForegroundWindow().

First, add this class to your project:

Imports System.Runtime.InteropServices

Public Class ProcessHelper
    <DllImport("User32.dll")>
    Private Shared Function SetForegroundWindow(handle As IntPtr) As Boolean
    End Function
    <DllImport("User32.dll")>
    Private Shared Function ShowWindow(handle As IntPtr, nCmdShow As Integer) As Boolean
    End Function
    <DllImport("User32.dll")>
    Private Shared Function IsIconic(handle As IntPtr) As Boolean
    End Function

    Private Const SW_RESTORE As Integer = 9

    Public Shared Sub BringProcessToFront(processName As String)
        ' Modern browsers run on multiple processes.
        ' We need to find the ones that have a WindowHandle.
        Dim processes = Process.GetProcessesByName(processName).
                            Where(Function(p) p.MainWindowHandle <> IntPtr.Zero)
        For Each p As Process In processes
            If BringProcessToFront(p) Then Exit Sub
        Next
    End Sub

    Public Shared Function BringProcessToFront(p As Process) As Boolean
        Dim windowHandle As IntPtr = p.MainWindowHandle
        If IsIconic(windowHandle) Then
            ShowWindow(windowHandle, SW_RESTORE)
        End If

        Return SetForegroundWindow(windowHandle)
    End Function
End Class

Then, you can use it like this:

ProcessHelper.BringProcessToFront("msedge") ' Tip: Use the process name without ".exe".

Thanks you. It's work. I've been blocked for two days. – Jason Madi Aug 18 '20 at 15:38 — Jason Madi, Aug 18 '20 at 15:38

Cannot bring a process to the front

1 Answers1