XSLT to handle quotes and Pipe Delimited symbol

Question

Experts, i need to write XSLT 1.0 code to remove the quotes for multiple conditions.

CASE1: Remove the double quotes CASE2: Remove the double quotes + delete the PIPE symbol inside that double quotes (IF exist) CASE3: Remove Single quote " from the input field.

Input:

<?xml version="1.0" encoding="UTF-8" standalone="no"?>
<ns0:Accounting xmlns:ns0="http://sample.com">
        <Record>
            <DRCR>"DR"</DRCR>
            <GLREFERENCE>"TEST|CASE"</GLREFERENCE>
            <GLVALUEDATE>EXAM"PLE</GLVALUEDATE>
            <GLACCOUNTNUMBER>"1160</GLACCOUNTNUMBER>
            <GLEXAMPLE>123</GLEXAMPLE>
            <GLEXAMPLE1>EXTRACT|2021-06-16|2853|1308026.7500|1176</GLEXAMPLE1>
        </Record>       
</ns0:Accounting>

** Desired Output:**

<?xml version="1.0" encoding="UTF-8" standalone="no"?>
<ns0:Accounting xmlns:ns0="http://sample.com">
        <Record>
            <DRCR>DR</DRCR>
            <GLREFERENCE>TEST CASE</GLREFERENCE>
            <GLVALUEDATE>EXAMPLE</GLVALUEDATE>
            <GLACCOUNTNUMBER>1160</GLACCOUNTNUMBER>
            <GLEXAMPLE>123</GLEXAMPLE>
<GLEXAMPLE1>EXTRACT|2021-06-16|2853|1308026.7500|1176</GLEXAMPLE1>
        </Record>       
</ns0:Accounting>

** XSLT I tried:**

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="text()">
    <xsl:call-template name="process">
        <xsl:with-param name="text" select="."/>
    </xsl:call-template>
</xsl:template>

<xsl:template name="process">
    <xsl:param name="text"/>
    <xsl:choose>
        <xsl:when test="contains($text, '&quot;')">
            <xsl:value-of select="substring-before($text, '&quot;')"/>
            <xsl:value-of select="translate(substring-before(substring-after($text, '&quot;'), '&quot;'), '|', '')"/>
            <xsl:call-template name="process">
                <xsl:with-param name="text" select="substring-after(substring-after($text, '&quot;'), '&quot;')"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

This XSLT not handling case 3, which has single quote in the input field. Please assist here..

Is there a case where you want to **keep** the double quotation mark character or the vertical bar character? — michael.hor257k, Oct 26 '21 at 08:52
Hi Michael, thanks for your response. Double quotation is not required, but vertical bar i need to keep in the input field for all the cases, except if vertical bar is inside double quotes then i need to remove that vertical bar. rest all cases i need to keep the vertical bar as it is. I updated the input example in the question. — Sree, Oct 26 '21 at 09:05
Can this be limited to remove vertical bar if the text starts and ends with quotes? — michael.hor257k, Oct 26 '21 at 09:40
Not exactly, if the input is ||||"TEST|CASE"|||| then expected output is ||||TEST CASE|||| — Sree, Oct 26 '21 at 10:20
This is a lot of work. Which processor are you using? It might be easier if some extension functions are available. — michael.hor257k, Oct 26 '21 at 10:30
OK, but which processor does it use? See here how to find out: https://stackoverflow.com/a/25245033/3016153 — michael.hor257k, Oct 26 '21 at 10:40
I have rolled your question back to what it was when I answered it. If you have a new question with different requirements, please post it separately. — michael.hor257k, Oct 28 '21 at 01:58

michael.hor257k · Answer 1 · 2021-10-26T11:01:32.910

Maybe something like this could work for you:

XSLT 1.0 (+ EXSLT node-set function)

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="text()">
    <xsl:choose>
        <xsl:when test="contains(., '&quot;')">
            <xsl:variable name="tokens">
                <xsl:call-template name="tokenize">
                    <xsl:with-param name="text" select="."/>
                </xsl:call-template>
            </xsl:variable>
            <xsl:for-each select="exsl:node-set($tokens)/token">
                <xsl:choose>
                    <xsl:when test="(position()=1 or position()=last()) and last() > 1">
                        <xsl:value-of select="."/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="translate(., '|', '')"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="."/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="'&quot;'"/>
        <xsl:variable name="token" select="substring-before(concat($text, $delimiter), $delimiter)" />
        <xsl:if test="$token">
            <token>
                <xsl:value-of select="$token"/>
            </token>
        </xsl:if>
        <xsl:if test="contains($text, $delimiter)">
            <!-- recursive call -->
            <xsl:call-template name="tokenize">
                <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
            </xsl:call-template>
        </xsl:if>
</xsl:template>

</xsl:stylesheet>

Note that this does not check the parity of the quotation marks. Any vertical bar character that is both preceded and followed by a quotation mark will be removed. For example, an input of:

<EXAMPLE>abc|123"def|456"ghi|789"jkl|012</EXAMPLE>

will be transformed to:

<EXAMPLE>abc|123def456ghi789jkl|012</EXAMPLE>

considering the complexity, after aligning with partner i updated the requirement in this question. existing XSLT is already removing vertical bar inside double quote. but these double quotes will not always comes in pair. please check once. — Sree, Oct 28 '21 at 01:30
AFAICT the stylesheet above provides the correct output in all your examples. In any case, I do not intend to change my answer every time you change your requirements. This is not a coding service. You are supposed to learn from the answers you get and implement their principles in your own work — michael.hor257k, Oct 28 '21 at 01:56

XSLT to handle quotes and Pipe Delimited symbol

1 Answers1