Why does "bCheck" always return "True"?

Question

I have been working on a Macro that will automatically add new Annual Worksheets when the Calendar Year Changes. My current Code is as follows:

Option Explicit

Sub addAnnualWkst()

Dim ws As Worksheet
Dim wsM As Worksheet
Dim strName As String
Dim strNamePreYr As String
Dim bCheck As Boolean
Dim pID As String
Dim rw

Set propIDs = ThisWorkbook.Names("propIDs").RefersToRange
Set actStatus = ThisWorkbook.Names("actStatus").RefersToRange

On Error Resume Next
Set wsM = Worksheets("WkstMaster")
    For rw = 1 To propIDs.Count
        If propIDs.Cells(rw, 1).Value2 <> vbNullString Then
            If actStatus.Cells(rw, 1).Value2 = True Then
              pID = propIDs.Cells(rw, 1).Value2
              strName = pID & "_" & (Format(Date, "yyyy"))
              strNamePreYr = pID & "_" & (Format(Date, "yyyy") - 1)
              bCheck = Len(Sheets(strName).Name) > 0
              Debug.Print pID, strName, strNamePreYr, bCheck
                If bCheck = False Then
                'add new sheet after Previous Year's Worksheet
                    wsM.Copy After:=Sheets(strNamePreYr)
                    ActiveSheet.Name = strName
                End If
            End If
        End If
    Next
Set wsM = Nothing
End Sub

the code above is based in part on on a Macro I found in a Tutorial I found and the Module Code is:

Option Explicit

Sub AddMonthWkst()
Dim ws As Worksheet
Dim wsM As Worksheet
Dim strName As String
Dim bCheck As Boolean

On Error Resume Next
Set wsM = Sheets("Wkst_Master")
strName = Format(Date, "yyyy_mm")
bCheck = Len(Sheets(strName).Name) > 0

If bCheck = False Then
'add new sheet after Instructions
    wsM.Copy After:=Sheets(1)
    ActiveSheet.Name = strName
End If

Set wsM = Nothing
End Sub

The above 'code' works as advertised! bCheck returns False and the new worksheet is added. I am able to rename the worksheet tab from the current month 05 to the previous month 04, save and close the workbook and when I reopen the workbook a new worksheet is automatically added with the 05 month extension.

I modified the code slightly to fit my needs and incapsulated that code in a subroutine I successfully use in different parts of the application where I select pIDs based on actStatus.

I have active Worksheet Tabs for the various PropIDs as shown in this image:

When I run the Macro the Immediate Window shows ALL Active pIDs with a pCheck Value as True when the pID "Rev" should return a value of False because pID "Rev" does not have a WorkSheet for the current year! As one can see for the Immediate window screenshot below, all the relevant pIDs are there!

If I disable the 'On Error Resume Next' line I get the Runtime Error: 9, Script out of range error and with or without the Error Trap the worksheet is not added. the Error happens at the highlighted line of code.

Please help me to resolve this issue. I know it is something simple I am missing! Thanks in advance.

I'm guessing you want to check if a sheet exists. If so, use [this approach](https://stackoverflow.com/questions/6688131/test-or-check-if-sheet-exists). — BigBen, May 10 '22 at 16:50
It returns true, as it's just chekcing the length of the proposed name for the new sheet. This will always be >0 due to adding `& "_" & (Format(Date, "yyyy"))` so if PID was empty, then it still would be true. As @bigben says, you're looking for the worksheet exists code. — Nathan_Sav, May 10 '22 at 16:55
@Nathan_Sav, the first line of code after the `For` statement ensures the `pID` cannot be `EMPTY`, and the secone `If` statements ensures that only `pIDs` with an `actStatus = True` are included in the list of worksheets to test. this is confirmed in the `Immediate Window` image I included! The `Screenshot` showing the worksheet tabs shows that `Rev_2022` does not exist! Why does `bCheck` return `True`? — hermannjt, May 10 '22 at 18:59
@BigBen, I took a look at the link in your comment and after sorting things out a bit, I came up with a solution based on the second `Answer` in that thread. You may see what I did in My answer. — hermannjt, May 10 '22 at 21:39

Tim Williams · Accepted Answer · 2022-05-10T23:00:10.283

This is your problem:

Sub TesterLoop()
    Dim bCheck As Boolean, s
    
    On Error Resume Next
    'Sheet4 doesn't exist
    For Each s In Array("Sheet1", "Sheet2", "Sheet4")
        'if the next line has an error then the value of bCheck is *unchanged*
        bCheck = Len(ThisWorkbook.Sheets(s).Name) > 0
        Debug.Print s, bCheck
    Next s
End Sub

Output:

Sheet1        True
Sheet2        True
Sheet4        True   '<<<oops!  Still has the Sheet2 value...

The value of bCheck can only be set when that line executes with no error: if there's an error then bCheck still has its initial False value, or the value from the previous loop iteration.

If you add

bCheck = False

before that line it will fix your problem.

But it's a bad idea to let On Error Resume Next cover that much of your code, and you'd be better off factoring out that check into a standalone function as suggested in the comments.

Tim, thanks for the pointers. I finally figured out who to use a `Function' with the original `Sub`. Everything works **WITHOUT** the need for `Error Handlers`. — hermannjt, May 11 '22 at 09:36

hermannjt · Answer 2 · 2022-05-11T16:57:02.033

Thanks to those who pointed me in direction of a possible solution.

Here is the the Solution I came up with!

Sub addAnnualWkst()

Dim ws As Worksheet
Dim wsM As Worksheet
Dim strName As String
Dim strNamePreYr As String
Dim bCheck As Boolean
Dim exists
Dim pID As String
Dim rw

Set propIDs = ThisWorkbook.Names("propIDs").RefersToRange
Set actStatus = ThisWorkbook.Names("actStatus").RefersToRange

Set wsM = Worksheets("WkstMaster")
    For rw = 1 To propIDs.Count
        If propIDs.Cells(rw, 1).Value2 <> vbNullString Then
            If actStatus.Cells(rw, 1).Value2 = True Then
              pID = propIDs.Cells(rw, 1).Value2
              cName = pID & (Format(Date, "yyyy"))
              strName = pID & "_" & (Format(Date, "yyyy"))
              strNamePreYr = pID & "_" & (Format(Date, "yyyy") - 1)
                If Not wsExists(strName) Then
                Debug.Print pID, strName, strNamePreYr
                  wsM.Copy After:=Sheets(strNamePreYr)
                  ActiveSheet.Name = strName
                End If
            End If
        End If
    Next
Set wsM = Nothing
End Sub

Function wsExists(strName As String) As Boolean
    Dim ws: For Each ws In ThisWorkbook.Sheets
    wsExists = (strName = ws.Name): If wsExists Then Exit Function
    Next ws
End Function

The only 'pID' that appears in the Immediate Window is the pID missing the 2022 extension.

`For Each ws In ThisWorkbook.Sheets` or you run the risk of a bug if your workbook is not the active workbook when this runs. — Tim Williams, May 11 '22 at 15:30

Why does "bCheck" always return "True"?

2 Answers2