How to repeat text in excel?

Question

I would like to ask for your advices. I have a problem with this enter image description here
I tried to use REPT in excel but the result show all multiplied word in on cell. How Can I improve it?

I want to result be like

enter image description here

and sort from Z to A by code. How can I do it. Thank you so much

score 3 · Answer 1 · answered Jun 01 '23 at 06:08

3

Try the following formula-

=DROP(TEXTSPLIT(CONCAT(REPT(A1:A3&"|",B1:B3)),,"|"),-1)

answered Jun 01 '23 at 06:08

Harun24hr

30,391
4
21
36

To sort in descending order, use `=SORT(DROP(TEXTSPLIT(CONCAT(REPT(A1:A3&"|",B1:B3)),,"|"),-1),,-1)`. – Harun24hr Jun 01 '23 at 06:33

JvdV · Answer 2 · 2023-06-01T07:04:25.787

2

This post and this one are very similar, if not a duplicate. Maybe the only thing that tells these apart is the fact that you seem to want a "z..a" order (which does not reflect in your desired result btw). I did implement it here below:

Formula in D1:

=SORT(XLOOKUP(SEQUENCE(SUM(B1:B3)),SCAN(0,B1:B3,LAMBDA(a,b,a+b)),A1:A3,,1),,-1)

edited Jun 01 '23 at 07:04

answered Jun 01 '23 at 06:58

JvdV

70,606
8
39
70

Ike · Answer 3 · 2023-06-01T06:31:11.480

1

Another solution - using MAKEARRAY:

=LET(d,A1:B3,
m,MAKEARRAY(ROWS(d),MAX(INDEX(d,,2)),LAMBDA(r,c,IF(c<=INDEX(d,r,2),INDEX(d,r,1),#N/A))),
SORT(TOCOL(m,2),,-1))

I added SORT at the end as you wrote "sort from Z to A by code"

edited Jun 01 '23 at 06:31

answered Jun 01 '23 at 06:28

Ike

9,580
4
13
29

`REDUCE()` will more easier with `EXPAND()` function. – Harun24hr Jun 01 '23 at 06:31
@Harun24hr: sorry, I don't get your point .... can you explain? – Ike Jun 01 '23 at 06:38
1

I meant to use `REDUCE()` function like `=DROP(REDUCE("",B1:B3,LAMBDA(a,x,VSTACK(a,EXPAND(INDEX(A1:A3,ROW(x)),x,,INDEX(A1:A3,ROW(x)))))),1)` – Harun24hr Jun 01 '23 at 06:51

How to repeat text in excel?

3 Answers3