XML Date Formatting using xsl

Question

I have a XML document. I am getting date from XML in this '2011-08-01' format. I have to display the same date using either Java Script or XSL in 'August 08th,2011' format. The XML tag is like this: <DatelineDate>2011-08-01</DatelineDate> Please help me to do this.

Answer 1

XSLT 1.0 is not a great technology for date formatting. You either have to do this manually with string processing, or via some XSLT parser specific extensions, for example the microsoft ms:format-date function. However, XSLT 2.0 does have the format-date as standard.

I would recommend using JavaScript instead. See this related question:

Where can I find documentation on formatting a date in JavaScript?

Answer 2

I. XSLT 2.0 solution:

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:output method="text"/>

 <xsl:template match="DatelineDate">
     <xsl:sequence select="format-date(xs:date(.), '[MNn] [D1o], [Y]')"/>
 </xsl:template>
</xsl:stylesheet>

when this transformation is applied on the provided XML document:

<DatelineDate>2011-08-01</DatelineDate>

the wanted, correct result is produced:

August 1st, 2011

Note: Saxon CE makes XSLT 2.0 available in the five major browsers.

---

II. XSLT 1.0 solution:

This is a simple and understandable solution, that doesn't rely on tricks and unreadable, hardcoded offsets.

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <my:months>
  <m num="1">January</m>
  <m num="2">February</m>
  <m num="3">March</m>
  <m num="4">April</m>
  <m num="5">May</m>
  <m num="6">June</m>
  <m num="7">July</m>
  <m num="8">August</m>
  <m num="9">September</m>
  <m num="10">October</m>
  <m num="11">November</m>
  <m num="12">December</m>
 </my:months>

 <xsl:variable name="vMonthNames" select=
  "document('')/*/my:months/*"/>

 <xsl:template match="DatelineDate">
   <xsl:variable name="vYear"
        select="substring-before(., '-')"/>
   <xsl:variable name="vdMonth" select=
    "substring-before(substring-after(., '-'), '-')"/>
   <xsl:variable name="vdDay" select=
    "substring-after(substring-after(., '-'), '-')"/>

   <xsl:variable name="vMonthName" select=
     "$vMonthNames[@num = number($vdMonth)]"/>

   <xsl:variable name="vordDaySuffix">
    <xsl:choose>
      <xsl:when test=
       "$vdDay mod 10 = 1
       and
        not($vdDay = 11)">st</xsl:when>
      <xsl:when test="$vdDay mod 10 = 2">nd</xsl:when>
      <xsl:when test="$vdDay mod 10 = 3">rd</xsl:when>
      <xsl:otherwise>th</xsl:otherwise>
    </xsl:choose>
   </xsl:variable>

     <xsl:value-of select=
     "concat($vMonthName,
             ' ',
             $vdDay, $vordDaySuffix,
             ', ',
             $vYear
             )
     "/>
 </xsl:template>

</xsl:stylesheet>

When this transformation is applied on the same XML document (above), again the wanted, correct result is produced:

August 01st, 2011

Answer 3

Have a look at these links:

1. http://www.w3.org/TR/xslt20/#date-time-examples, and
2. ms:format_date function

Answer 4

Here's a simple template I use in XSLT 1.0 sometimes

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:variable name="months" select="'January  February March    April    May      June     July     August   SeptemberOctober  December '" />
 <xsl:variable name="dayord" select="'-stndrdthththththththththththththththththstndrdthththththththst'" />

 <xsl:template match="DatelineDate">
  <xsl:value-of select="normalize-space(concat(
    substring($months,substring(.,6,2) * 9 - 8, 8),
    ' ',
    substring(.,9,2) + 0,
    substring($dayord,substring(.,9,2)*2,2),
    ', ',
    substring(.,1,4)
   ))" />
 </xsl:template>

</xsl:stylesheet>

The substrings are a little convoluted, but they basically pick out the appropriate month name and date suffix from two variables. NB: The spacing in those variables is important, the month names MUST be 9 characters apart. The +0 on the 3rd line of that concat is just a simple trick to treat it as a number rather than the text 01; Leave that out if you actually prefer the 01 formatting.