Temporarily interrupt SETLOCAL

Question

I have a script that has a lot of use of the SETLOCAL ENABLEDELAYEDEXPANSION command, so I start the script off that way (less headaches). However, it does not allow you to use the ! character without escaping each instance of it (and I want to create a long line of !s for an error logging section =D ) and I don't want to escape every one of them.

Is there a way to temporarily break out of SETLOCAL, then reenter it keeping all previously created variables within the original SETLOCAL?

For example:

SETLOCAL ENABLEDELAYEDEXPANSION
set var=HELLO
ECHO %var%
ENDLOCAL

SETLOCAL ENABLEDELAYEDEXPANSION
ECHO %var%

The 2nd ECHO will not give you the previous value of var

EDIT: ^ will not allow you to escape the ! inside SETLOCAL ENABLEDELAYEDEXPANSION

What's with 'setlocal DisableDelayedExpansion ... Endlocal' ? — jeb, Jan 17 '12 at 19:15
@jeb but enabling setlocal enabledelayedexpansion after an endlocal will not keep all variables created within the previous setlocal command. — Anthony Miller, Jan 17 '12 at 19:16

score 1 · Answer 1 · answered Jan 18 '12 at 04:00

1

setlocal DisableDelayedExpansion
set var=Value! with! many! Bangs!
setlocal EnableDelayedExpansion
echo !var!

answered Jan 18 '12 at 04:00

Aacini

65,180
12
72
108

score 1 · Answer 2 · edited May 23 '17 at 10:34

You can nest it like Aacini shows it.
Or you can use the return technic or escape ! inside a EnableDelayed block with ^^!

Setlocal EnableDelayedExpansion
echo 1^^!^^!^^!^^!^^!^^!^^!
REM *** Or use a self removing quote
echo !="! 2^!^!^!^!^!^!

Setlocal DisableDelayedExpansion
echo 3 !!!!!!!!
set var=Hello
(
  endlocal
  rem Bring the value behind the endlocal barrier
  set var=%var%
)

echo var is still there, %var%

The return technic can also be used for exclamation marks, but then it is a bit more complex.
It can be found at Make an environment variable survive ENDLOCAL

Temporarily interrupt SETLOCAL

2 Answers2