This is for Linux running in Windows 10 (Ubuntu), also known as WSL. It's not the same as Cygwin and Windows or stand alone Linux. It is its own beast.
Does anyone know how to make the copy and paste work off of the Windows clipboard OR the WSL Ubuntu Linux emulation? I am using set clipboard=unnamedplus. It's not working, not matter what combinations I use like yy, "+yy, etc.
Yes, it's vim-gtk with +xterm_clipboard support.
(Edit: Apr 2024) With the latest WSL version: 2.1.5.0 on Win11 simply having set clipboard+=unnamedplus now seems to be enough for neovim, at least with the latest Microsoft Store versions of Ubuntu.
(Edit: Oct 2020) For 2-way clipboard on neovim, I have been using win32yank for several months with no issues. Put win32yank.exe somewhere in your path on Linux (anywhere should be fine), and add the following to your init.vim.
set clipboard+=unnamedplus
let g:clipboard = {
\ 'name': 'win32yank-wsl',
\ 'copy': {
\ '+': 'win32yank.exe -i --crlf',
\ '*': 'win32yank.exe -i --crlf',
\ },
\ 'paste': {
\ '+': 'win32yank.exe -o --lf',
\ '*': 'win32yank.exe -o --lf',
\ },
\ 'cache_enabled': 0,
\ }
(Original answer) If you just want to yank from VIM to Windows, for WSL2 and Ubuntu 20.04, this answer on Reddit worked perfectly for me with standard VIM and standard WSL2 Ubuntu.
Put the following in your .vimrc (at the bottom, for example):
" WSL yank support
let s:clip = '/mnt/c/Windows/System32/clip.exe' " change this path according to your mount point
if executable(s:clip)
augroup WSLYank
autocmd!
autocmd TextYankPost * if v:event.operator ==# 'y' | call system(s:clip, @0) | endif
augroup END
endif
This solution worked for me, thanks to github user robbiev.
For completion this is an outtake from his answer:
Go with all the defaults options, and ensure the clipboard options are checked.
At the end, save the configuration to a file, config.xlaunch (use that to start it from now on).
Put export DISPLAY=localhost:0.0 in your .bashrc in bash for Windows and run source ~/.bashrc in any open terminal.
Ensure vim is installed using clipboard support. vim --version | grep clipboard should say +clipboard, not -clipboard. Also if you run the ex command :echo has('clipboard') in vim and it says 0 it does not have clipboard support compiled in.
If you don't have clipboard support, install a vim package compiled with clipboard support, e.g. apt-get install vim-gtk.
Now you can access the Windows system clipboard via "*p and "*y, or set it to default by putting set clipboard=unnamed in your .vimrc file.
As robbiev mentions you should now also be able to use the Windows clipboard from remote machines using SSH X forwarding.
You can right click the terminal then in the options box check CTRL + SHIFT + C/V for copy paste operations through the terminal.
The following worked for me (2023/05/15, WSL Ubuntu 20.04.5 LTS):
Ensure your WSL has X11 support: https://learn.microsoft.com/en-us/windows/wsl/tutorials/gui-apps
Ensure vim is installed with clipboard support. Running vim --version | grep clipboard should say +clipboard, not -clipboard.
If you don't have clipboard support, install a vim package compiled with clipboard support:
sudo apt-get install vim-gtk
(This is similar to Aerows answer but you don't need VcXsrv)
If you are using vim(or neovim), maybe you should know ANSI OSC52 that is a standard which trys to solve this "copy/paste" problem(in specific cases, e.g. in a SSH terminal).
Then here's on useful plugin vim-oscyank which implements this standard and what you have to do is just install this plugin and set a keymapping for it. You should definitely give it a try.
Here's a simple 2023 solution with no third-party software:
vnoremap <C-c> y:!echo <C-r>=escape(substitute(shellescape(getreg('"')), '\n', '\r', 'g'), '#%!')<CR> <Bar> clip.exe<CR><CR>
Highlight text in visual mode (visual, visual line, or visual block) and pressCtrl-c.
First, yank the selection. Then insert it into the command line using getreg('"'). Then, use shellescape to handle the quotations. Then substitute out the newline characters with carriage returns using substitute. Then use escape to convert any !, %, or # characters to \!, \%, or \#, respectively. Finally, insert all that and use <Bar> clip.exe to pass the entire thing to clip.exe.
vnoremap <C-c> ::w !clip.exe<CR><CR>
Highlight text in visual mode and pressCtrl-c.
: gets you into command mode (which will give you '<,'>). Then :w will pass the selection to a command. Using ! means it's an external command, which is clip.exe here. Finally, you need 2 <CR>s: one to execute the command and one get out of the subshell.
If you have enabled the QuickEdit Mode, you can just select the text with your mouse and right click to copy it into the clipboard.
For enabling the QuickEdit Mode, just right-click on the console windows on top and select Properties (and/or Default), then tick QuickEdit Mode.
EDIT: Out-of-the-box, it is not possible to copy from VIM into Windows clipboard currently. However, on a GitHub-Issue within the WSL repository, some guys seem to have found a way to do that using Xming or VcXsrv respectively: https://github.com/Microsoft/WSL/issues/892#issuecomment-275873108.
EDIT2: Another try using .vimbuffer: https://stackoverflow.com/questions/44480829/how-to-copy-to-clipboard-in-vim-of-bash-on-windows
Not sure why nobody mentioned ConEmu. It can at minimum handle one-half of the clipboard issue:
To paste Windows clipboard stuff into WSL, normal Ctrl + V will get things right.
c:/users/name will be transcribed into /mnt/c/users/name. This is runnable through WSL natively.To copy from WSL, for now, I would still have to use my house cursor. It works more than 90% of the times.
Per my use case, I don't tend to copy from WSL a lot; and have been enjoying the pasting-help by ConEmu a lot.
There are lots of quirks with WSL terminal, but using cross Vim copy/paste is top annoyance in my book. Nothing I tried as of April 2018 worked for pasting into Vim or other areas (using normal saneness) so, let's try to bypass the issue, and others related like buffer, for now. This is not a direct WSL solution, rather a workaround using a better terminal + SSH until MS provides a fix.
Putty, or it's extended fork Kitty, offer a more robust terminal compared to WSL. We can connect to the WSL (or any of your other servers) using SSH via localhost, using a custom port, and get a fuller featured terminal, including almost all Vim capabilities for bi-directional, or native pasting, scroll, etc. [You may need to tweak Vim conf to trigger all capabilities].
Putty/Kitty require an SSH server available in WSL, on a custom localhost port. If you haven't set up a localhost SSH server on your WSL already, here's a quick overview of how:
Step 1) Open the Ubuntu WSL terminal, do a sudo su to auth as root, run vim /etc/ssh/sshd_config to open SSH server conf.
Step 2) Look for "Port" near the first handful of lines. It may be set to 22. We need to set a custom port for our WSL SSH that doesn't collide. Hit i to edit. Let's use port 9977 for example.
Step 3) If you're a dev, or otherwise don't need to bother with keys for your localhost WSL SSH, look for password authentication. You can set PasswordAuthentication yes. Else, keys and higher security, or public access through firewall(s) on WSL, are beyond the scope of this answer.
Step 4) When done editing, hit esc to exit edit mode, then save+quit the file :wq. Restart ssh service using service ssh restart. Leave WSL open at this point as a master console.
Step 5) Create a new Putty/Kitty session, connect to localhost, using your custom port (9977 in our example). Log in with your WSL credentials, sudo su if you require root. You should now have a much more robust shell available. Repeat or screen as many views as you need.
I know it's not a direct answer, but at least it's a solution for now :)
You could use xclip or win32yank.exe. For some reason sometimes in WSL1 my clip.exe and win32yank.exe seem to have some runtime error so I am using mainly local xclip with an xserver running. Modified from a few other examples including a neovim clipboard .vim
You could just use top section to add ctrl-c ctrl-x (no ctrl-v yet!) without affecting how vim works aready, or add bottom section to yank to windows clipboard but have delete work normally using vim buffer (so hitting x etc still works quickly and as expected)
set clipboard=unnamedplus
if system('uname -a | egrep [Mm]icrosoft') != ''
let g:lastyank = 'y'
if executable('win32yank.exe')
let g:copy = 'win32yank.exe -i --crlf'
let g:paste = 'win32yank.exe -o --lf'
elseif exists('$DISPLAY') && executable('xclip')
let g:copy = 'xclip -i -selection clipboard'
let g:paste = 'xclip -o -selection clipboard'
else
let g:copy = 'clip.exe'
let g:paste = 'powershell.exe Get-Clipboard'
endif
augroup myYank
autocmd!
autocmd TextYankPost * if v:event.operator == 'y' | call system(g:copy, @") | let g:lastyank='y' | else | let g:lastyank='' | endif
"autocmd TextYankPost * if v:event.operator ==# 'y' | call system(g:copy, @") | endif
"autocmd TextYankPost * call system(g:copy, @")
augroup END
function! Paste(mode)
if g:lastyank == 'y'
let @" = system(g:paste)
endif
return a:mode
endfunction
map <expr> p Paste('p')
map <expr> P Paste('P')
" map Ctrl-c and Ctrl-x as expected
func! GetSelectedText()
normal gv"xy
let result = getreg("x")
return result
endfunc
noremap <C-c> :call system(g:copy, GetSelectedText())<CR>
noremap <C-x> :call system(g:copy, GetSelectedText())<CR>gvx
endif
You can open wsl distribution from Windows Terminal, then press Ctrl +Shift + V.
Open Windows Terminal, then click in "down arrow"
Open vim and go to Insert mode and press Ctrl + Shift + V
If you want, you can get content from the "+" register and then paste with < leader > p
" Copy to clipboard
vnoremap <leader>y "+y
nnoremap <leader>y "+y
" " Paste from clipboard
nnoremap <leader>p "+p
vnoremap <leader>p "+p
Lots of suggestions for the copy but I couldn't get any working for paste. I just settled for this in my vimrc
nmap PP :r!powershell.exe -command "Get-Clipboard"<CR>
This solution involves no additional plugins.
With the following script in .vimrc:
vnoremap <leader>y y<esc>:call system('clip.exe', @")<CR>
we can copy from vim by
\ by default) followed by y.Now the selection is in the windows clipboard. Note that, the copied text will keep the original line break.
What does it do: y<esc> yanks selected texts into register @". The function system save the register to a temporary file and then pipe it to clip.exe.
The best way in my opinion is to use the terminal paste by Ctrl + Shift + V. It avoids the problem of line break by simulating user input.
Don't forget to set pastetoggle in vim so that automatic indentation does not ruin your editing.
However, if you have large text, you might want to paste directly to vim. With the following line
nnoremap <leader>p <esc>:let @"=system('powershell.exe Get-Clipboard')<CR>""p
you can paste by pressing leader key and p. Note that the carrige returns will remain in the text.
To strip \r while pasting, instead use
nnoremap <leader>p <esc>:let @"=substitute(system('powershell.exe Get-Clipboard'), '\r', '', 'g')<CR>""p
Adding to above the answer titled MAY 2023 SOLUTION, I just want to say that sudo apt install vim-gtk3 gave me the X11, clipboard, and xterm_clipboard features.
Details: JAN 2025 I installed WSL2 with distribution Ubuntu on Windows 11. For context, this is my installation version:
> wsl --version: WSL version: 2.3.26.0, Kernel version: 5.15.167.4-1$ uname -srm: Linux 5.15.167.4-microsoft-standard-WSL2 x86_64This Ubunutu distribution came with Vim 9.1 already installed but without support for X11, clipboard, or xterm_clipboard (check this from bash with $ vim --version or, from the Vim cmdline, with :ver).
Following the recommendation in the MAY 2023 SOLUTION:
sudo apt install vim-gtk3
That installs vim.gtk3 which is the "Huge version with GTK3 GUI".
Thankfully, I am able to run this as vim (I don't need to use vim.gtk3 or create an alias). The next time I ran vim and checked the registers from the Vim cmdline with :reg, I saw that the clipboard from other applications was available in both the * and + registers.
No plugins/3rd party software, normal y and p with no key mapping
I'm using Windows Terminal, WSL2 running Debian, sudo apt install vim-gtk3 for its +clipboard feature
.vimrc:
" For WSL conditionals
function! IsWSL()
if has("unix") && filereadable("/proc/version")
" avoid error on Android
let lines = readfile("/proc/version")
if lines[0] =~ "microsoft"
return 1
endif
endif
return 0
endfunction
" Set clipboard on WSL
if IsWSL()
set clipboard=unnamedplus
let g:clipboard = {
\ 'name': 'WslClipboard',
\ 'copy': {
\ '+': 'clip.exe',
\ '': 'clip.exe',
\ },
\ 'paste': {
\ '+': 'powershell.exe -c [Console]::Out.Write($(Get-Clipboard -Raw).tostring().replace("r", ""))',
\ '': 'powershell.exe -c [Console]::Out.Write($(Get-Clipboard -Raw).tostring().replace("r", ""))',
\ },
\ 'cache_enabled': 0,
\ }
endif
Adapted from Reddit comment
