Win10: Change default folder optimization

Question

Using Windows 10, I prefer to treat all folders as "General Items" and use Detail view. When I create a new folder containing only a few WAV files, the folder optimization automatically changes to "Music". Similarly, if I create a folder containing a few video clips, it changes to "Videos". How can I prevent this?

I'm not talking about libraries. This affects even folders on a secondary hard drive.

Answer 1

Here are a couple of .bat files that will do that.

Reset_Folder_View_Settings_of_All_Folders_to_Default.bat

@echo off
:: To reset folder view settings of all folders
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\Shell\BagMRU" /F
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\Shell\Bags" /F
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\ShellNoRoam\Bags" /F
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\ShellNoRoam\BagMRU" /F
Reg Delete "HKCU\SOFTWARE\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" /F
Reg Delete "HKCU\SOFTWARE\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" /F
Reg Delete "HKCU\SOFTWARE\Classes\Wow6432Node\Local Settings\Software\Microsoft\Windows\Shell\Bags" /F
Reg Delete "HKCU\SOFTWARE\Classes\Wow6432Node\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" /F

:: Reset "Apply to Folders" views to default
REG Delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Streams\Defaults" /F

:: Reset size of details, navigation, preview panes to default
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Modules\GlobalSettings\Sizer" /F

:: Kill and restart explorer
taskkill /f /im explorer.exe
start explorer.exe

All_Folders_Use_General_Items_Folder_Template.bat

@echo off
REG ADD "HKCU\SOFTWARE\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags\AllFolders\Shell" /V FolderType /T REG_SZ /D NotSpecified /F
:: Kill and restart explorer
taskkill /f /im explorer.exe
start explorer.exe

Source: How to Change the Template of a Drive, Folder, or Library in Windows 10.