How can I prevent an app (specifically zoom) from running in the background when I close it?

Question

When I close a certain app (Zoom) it appears in my notification area and continues to run as a background process. I have to manually right click and exit the program (or open task manager and exit) each time. How can I prevent it from running as a background process and force it to automatically shut down completely when I close the program?

Note: It doesn't appear in settings>privacy>background apps. I already checked that.

Answer 1

This annoys me too, so I wrote a oneline AutoHotKey script for this:

^q::run, taskkill /f /im zoom.exe

This does the following:

• ^q means control + q. You can change this to another shortcut if you like, I'm just used to using this already for closing programs.
• run, runs the following command in a CMD shell.
• taskkill lets us kill the specified process.
• /f /im zoom.exe means to force close the process called zoom.exe.

If you're new to AHK, you can use the snippet in the following way:

1. Download and install AHK.
2. Save the above script into a file with an .ahk extension.
3. You can add the script to your startup folder (or add a shortcut to it) so it will run in the background when you start your computer.
4. Just remember to ctrl+q when you're done with zoom to close it :)

Answer 2

I put together a script that will close zoom (if it isn't in a meeting) when Alt+F4 was pressed or to close it outright if Alt+Ctrl+F4 was pressed, both shortcuts still work normally if zoom isn't the selected window.

;Alt + F4 (will close zoom if it is the selected window except during a meeting)
$!F4::
if WinActive("ahk_exe Zoom.exe")
    {
    if WinExist("Zoom Meeting")
        {
        return
        }
    else
        {
        Run cmd.exe /c taskkill /F /IM zoom.exe,, hide
        }
    }
else
    {
    send !{F4}
    }
return
;Alt + Ctrl + F4 (will close zoom if it is the selected window)
$!^F4::
if WinActive("ahk_exe Zoom.exe")
    {
    Run cmd.exe /c taskkill /F /IM zoom.exe,, hide
    }
else
    {
    send !^{F4}
    }
return

I have also compiled the above script into an executable file, this allows it to work even if you don't have AutoHotKey installed.

Download it Here.

Answer 3

An alternative solution. This one does not rely on mouse coordinates but responds to the Windows "Close" message:

#IfWinActive ahk_class ZPPTMainFrmWndClassEx
~LButton::
    CoordMode, Mouse, Screen
    MouseGetPos, X, Y, HWND
    if !(HWND = WinExist("Zoom Meeting")) {
        SendMessage, 0x84,, (Y << 16)|X,, ahk_id %HWND%
        if (ErrorLevel = 20)
            Process, Close, zoom.exe
    }
return

Answer 4

The only reliable way to do this is:

1. Remember which specific apps have this "always minimize to system tray when user closes window" and instead of closing the window, mouseover the systray icon, click and select Exit.
2. Automate the above process with AutoHotKey or similar (beyond my abilities).
3. Write a background Windows 10 app to allow administrator to disable a list of programs from running in the background, alt. always exit application when user clicks the X to close a window.

Answer 5

It's an ad hoc solution, but it may be helpful for you. You click the Close button, AutoHotKey kills the zoom process. The position pixel numbers 2, 78 and 43 are for my PC, you may need to adjust them to your PC.

For people you don't know AutoHotKey, download it here and install. Then, make a text file with "quit-zoom.ahk" or something like that and paste the code into it. You can put the ahk file in the Windows startup folder.

#IfWinActive, ahk_class ZPPTMainFrmWndClassEx 
~LButton::
  CoordMode Mouse, Window
  MouseGetPos MX, MY
  WinGetPos, WX, WY, WW, WH, A
  X := WW - MX 
  Y := MY
  if (X > 2 && X < 78 && Y > 2 && Y < 43) {
    Sleep, 500
    Process, Close, zoom.exe
  }
  Return
#IfWinActive

Answer 6

As someone said - we can create work around, but Zoom designers thinking that 'X' means run in background is a flaw. They should have atleast given the user a choice to select "exit" or "run in background" in settings.

In a similar tone, I hate when program installation thinks that a shortcut on desktop should be created...

Answer 7

There is now an Quit Zoom option from the Taskbar.

Answer 8

I literally made an account just to add another solution here, it's based on The Dimension of Eternity

but its been upgraded to V2 and also have added a new section to check for CptHost.exe process change which is what actual zoom meetings use.

so any time you exit out, or leave a meeting, it will actually kill zoom workspace too.

#Requires AutoHotkey v2.0
#SingleInstance Force
SetWorkingDir(A_ScriptDir)
; Alt + F4 hotkey
!F4::{
    if WinActive("ahk_exe Zoom.exe") {
        if WinExist("Zoom Meeting") {
            return
        } else {
            Run('cmd.exe /c taskkill /F /IM zoom.exe',, "Hide")
        }
    } else {
        Send("!{F4}")
    }
}
; Alt + Ctrl + F4 hotkey
!^F4::{
    if WinActive("ahk_exe Zoom.exe") {
        Run('cmd.exe /c taskkill /F /IM zoom.exe',, "Hide")
    } else {
        Send("!^{F4}")
    }
}
; Initialize process monitoring
global LastCptHostState := 0
global LastCptHostPID := 0
; Initial process check
ProcExists := ProcessExist("CptHost.exe")
if ProcExists {
    LastCptHostState := 1
    LastCptHostPID := ProcExists
}
; Process monitoring timer
SetTimer(CheckCptHost, 1000)
CheckCptHost() {
    global LastCptHostState, LastCptHostPID
    CurrentState := ProcessExist("CptHost.exe")
if CurrentState {
    if (!LastCptHostState) {
        LastCptHostPID := CurrentState
    }
} else if LastCptHostState {
    Run('cmd.exe /c taskkill /F /IM zoom.exe',, "Hide")
}
LastCptHostState := CurrentState

}

You can also find the it at my github

I did not compile into .exe as i dont think you should run unknown exe on your machine. install Ahk2Exe to do that for you!