How can I make icons in the Windows 10 taskbar/quicklaunch/tray darker to help prevent burn-in on my OLED display?

Question

OLED panels are susceptible to burn-in. How can I make the taskbar/tray and quicklaunch icons/text (even if it makes the taskbar itself) darker? I know about the dark theme, but please understand that does not make the icons in the taskbar and quicklaunch bar darker, only the bar's background colour.

Please also note, I do NOT want to autohide the taskbar/tray, as I've heard a million people recommend that, but it's not for me.

harrymc · Accepted Answer · 2021-12-07T20:38:37.523

You can use the free AutoHotkey.

The following AutoHotkey script will cover the taskbar with a semi-transparent window that is click-through, but will hide it when a window becomes full-screen:

SysGet, Monitor, Monitor                   ; Get monitor dimensions
SysGet, WorkArea, MonitorWorkArea          ; Get monitor work-area without taskbar
dimtop := % WorkAreaBottom + 1             ; taskbar is assumed to start below the work-area
Gui Color, 0,0                             ; Black color
Gui -Caption +ToolWindow +E0x20            ; No title bar, No taskbar button, Transparent for clicks
Gui Show, X0 Y%dimtop% W%MonitorRight% H63 ; Create a semi-transparent cover window
WinGet ID, ID, A                           ; Get its HWND/handle ID
Winset AlwaysOnTop,ON,ahk_id %ID%          ; Keep it always on the top
WinSet Transparent,99,ahk_id %ID%          ; Transparency 99/256
SetTimer, coverIt, 500                     ; Repeat setting it to be on top of the taskbar
return
coverIt:
    WinGet style, Style, A                 ; Get active window style and dimensions
    WinGetPos ,,,winW,winH, A
    ; 0x800000 is WS_BORDER.
    ; 0x20000000 is WS_MINIMIZE.
    ; check no border and not minimized
    isfull := ((style & 0x20800000) = 0 and winH >= A_ScreenHeight and winW >= A_ScreenWidth)
    if (isfull) {
        WinHide, ahk_id %ID%
    } else {
        WinShow, ahk_id %ID%
        Winset AlwaysOnTop,ON,ahk_id %ID%      ; Ensure it is still on the top
    }
    return

After installing AutoHotKey, put the script in a .ahk file and double-click it to test. You may stop the script by right-click on the green H icon in the traybar and choosing Exit. To have it run on login, place it in the Startup group at C:\Users\USER-NAME\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup.

score 2 · Answer 2 · answered Nov 21 '23 at 12:55

Just wanted to update the script provided by @harrymc and asked by @ccrez. You can find it on my website here.

I made so that the script deactivate if you're on your primary monitor in full screen but not if it is an app in a secondary monitor that is in full screen.

Goal

Auto-dim the taskbar to prevent burn in.
Keep the dimming when an app is opened in full-screen on a second monitor.
Stop the dimming if an app is opened full-screen on the primary monitor.

Sources

Reddit source : Screensaver and taskbar dimmer for protecting OLED displays during Windows desktop and gaming usage scenarios : r/OLED_Gaming
StackOverflow reference with script : How can I make icons in the Windows 10 taskbar/quicklaunch/tray darker to help prevent burn-in on my OLED display? - Super User
Detecting full screen app to stop dimming : Detect Fullscreen application? - Ask for Help - AutoHotkey Community
Detecting the screen the current window is on : Detecting the screen the current window is on - Ask for Help - AutoHotkey Community

Script

SysGet, Monitor, Monitor                   ; Get monitor dimensions
SysGet, WorkArea, MonitorWorkArea          ; Get monitor work-area without taskbar
dimtop := % WorkAreaBottom + 1             ; taskbar is assumed to start below the work-area
Gui Color, 0,0                             ; Black color
Gui -Caption +ToolWindow +E0x20            ; No title bar, No taskbar button, Transparent for clicks
Gui Show, X0 Y%dimtop% W%MonitorRight% H63 ; Create a semi-transparent cover window
WinGet ID, ID, A                           ; Get its HWND/handle ID
Winset AlwaysOnTop,ON,ahk_id %ID%          ; Keep it always on the top
WinSet Transparent,99,ahk_id %ID%          ; Transparency 99/256
SetTimer, coverIt, 500                     ; Repeat setting it to be on top of the taskbar
return
GetCurrentMonitor()
{
  SysGet, numberOfMonitors, MonitorCount
  WinGetPos, winX, winY, winWidth, winHeight, A
  winMidX := winX + winWidth / 2
  winMidY := winY + winHeight / 2
  Loop %numberOfMonitors%
  {
    SysGet, monArea, Monitor, %A_Index%
    if (winMidX > monAreaLeft && winMidX < monAreaRight && winMidY < monAreaBottom && winMidY > monAreaTop)
      return A_Index
  }
  SysGet, primaryMonitor, MonitorPrimary
  return "No Monitor Found"
}
coverIt:
    WinGet style, Style, A                 ; Get active window style and dimensions
    WinGetPos ,,,winW,winH, A
    ; 0x800000 is WS_BORDER.
    ; 0x20000000 is WS_MINIMIZE.
    ; check no border and not minimized
    isfull := ((style & 0x20800000) = 0 and winH >= A_ScreenHeight and winW >= A_ScreenWidth)
    isPrimaryMonitor := (GetCurrentMonitor() = 1)
    if (isfull and isPrimaryMonitor) {
        WinHide, ahk_id %ID%
    } else {
        WinShow, ahk_id %ID%
        Winset AlwaysOnTop,ON,ahk_id %ID%      ; Ensure it is still on the top
    }
    return

HELIX · Answer 3 · 2024-05-12T22:29:37.033

I took the script @harrymc provided and converted it for AutoHotkeys version 2. Had to add a try/catch block because in version 2 it would occasionally throw errors when opening the start menu. The catch block is empty, as there isn't anything to do in terms of error handling (just continue). There are probably better solutions to this, but it does work for me.

EDIT 13 MAY 2024: AUTOMATICALLY DETERMINE HEIGHT OF TASKBAR

; DIM TASKBAR FOR AUTOHOTKEYS V2
MonitorGet(, &MonitorLeft, &MonitorTop, &MonitorRight, &MonitorBottom)                   ; Get monitor dimensions
MonitorGetWorkArea(, &WorkAreaLeft, &WorkAreaTop, &WorkAreaRight, &WorkAreaBottom)          ; Get monitor work-area without taskbar
dimtop := WorkAreaBottom              ; taskbar is assumed to start below the work-area
dimheight := MonitorBottom - WorkAreaBottom ; determine height of taskbar
myGui := Gui()
myGui.BackColor := "0"                             ; Black color
myGui.Opt("-Caption +ToolWindow +E0x20")            ; No title bar, No taskbar button, Transparent for clicks
myGui.Show("X0 Y" . dimtop . " W" . MonitorRight . " H" . dimheight) ; Create a semi-transparent cover window
ID := WinGetID("A")                           ; Get its HWND/handle ID
WinSetAlwaysOnTop(1, "ahk_id " ID)          ; Keep it always on the top
WinSetTransparent(128, "ahk_id " ID)          ; Transparency 128/256 = 50%
SetTimer(coverIt,100)                     ; Repeat setting it to be on top of the taskbar
return
coverIt()
{
    try 
    {
        style := WinGetStyle("A")                 ; Get active window style and dimensions
        WinGetPos(, , &winW, &winH, "A")
        ; 0x800000 is WS_BORDER.
        ; 0x20000000 is WS_MINIMIZE.
        ; check no border and not minimized
        isfull := ((style & 0x20800000) = 0 and winH >= A_ScreenHeight and winW >= A_ScreenWidth)
        if (isfull) {
            WinHide("ahk_id " ID)
        } else {
            WinShow("ahk_id " ID)
            WinSetAlwaysOnTop(1, "ahk_id " ID)      ; Ensure it is still on the top
        }
    }
    catch 
    {
        ; NOOP
    }
    return
}

score 0 · Answer 4 · answered Nov 28 '21 at 22:18

If you do not want to set the taskbar to auto-hide, so it appears only when your cursor is upon it, which is the simplest and most effective solution, then you might try third-party software, such as free Open-Shell Menu.

Open-Shell Menu lets you set the transparency and color of the taskbar and the color of the text, though the icons themselves do not appear to be affected. To do so, you'd need to find or to create a custom icon for each item in the Start Menu, and to modify the executable to change its own icon.

If you find erratic taskbar behavior an issue in auto-hide mode, try another third-party tool, such as Taskbar Activate or an alternative.

How can I make icons in the Windows 10 taskbar/quicklaunch/tray darker to help prevent burn-in on my OLED display?

4 Answers4

Goal

Sources

Script