1

Earlier I asked a question about how to open sound settings using a shortcut.

This is the question: A shortcut on desktop for opening advanced sound output page

It was working fine until windows updated. Now, I can't open it.

The shortcut path was: ms-settings:apps-volume

Also, the shortcut used to look like the settings icon but now, it is this

enter image description here

How can I get back my shortcut?

vickyace
  • 377

1 Answers1

0

Give a try for this vbscript and tell me the results on your side. Tested on Windows 10 (32 bits) and works for me 5/5 even with a hotkey Ctrl + Alt + V

Option Explicit
Const Title = "Create a Shortcut for Apps-Volume-Settings on Desktop" 
Create_Shortcut Array("Desktop","Apps-Volume-Settings","ms-settings:apps-volume","","%SystemRoot%\system32\shell32.dll,138","","CTRL+ALT+V")
MsgBox "Shortcut of ""ms-settings:apps-volume is created"" on your Desktop",vbInformation+vbSystemModal,Title
'-------------------------------------------------------------------------------------------------------
Sub Create_Shortcut(rArgs) 
    Dim objShell,DesktopPath,objShortCut,ObjShortcutPath
    Dim ShortcutName,ShortcutPath,ShortcutLocation,TargetPath,Arguments,IconLocation,Description,HotKey
    Set objShell = CreateObject("WScript.Shell")
    Select Case UBound(rArgs)
    Case 2
        ShortcutLocation = cstr(rArgs(0))
        ShortcutPath     = objShell.SpecialFolders(ShortcutLocation)
        ShortcutName     = cstr(rArgs(1))
        Set objShortCut  = objShell.CreateShortcut(ShortcutPath & "\" & ShortcutName & ".lnk")
        TargetPath   = cstr(rArgs(2))
        objShortCut.TargetPath = chr(34) & TargetPath & chr(34)
        objShortCut.Save
    Case 3
        ShortcutLocation = cstr(rArgs(0))
        ShortcutPath     = objShell.SpecialFolders(ShortcutLocation)
        ShortcutName     = rArgs(1)
        Set objShortCut  = objShell.CreateShortcut(ShortcutPath & "\" & ShortcutName & ".lnk")
        TargetPath   = cstr(rArgs(2))
        objShortCut.TargetPath = chr(34) & TargetPath & chr(34)
        Arguments = cstr(rArgs(3))
        objShortCut.Arguments = Arguments
        objShortCut.Save
    Case 4
        ShortcutLocation = cstr(rArgs(0))
        ShortcutPath     = objShell.SpecialFolders(ShortcutLocation)
        ShortcutName     = rArgs(1)
        Set objShortCut  = objShell.CreateShortcut(ShortcutPath & "\" & ShortcutName & ".lnk")
        TargetPath   = cstr(rArgs(2))
        objShortCut.TargetPath = chr(34) & TargetPath & chr(34)
        Arguments = cstr(rArgs(3))
        objShortCut.Arguments = Arguments
        IconLocation = cstr(rArgs(4))
        ObjShortCut.IconLocation = IconLocation
        objShortCut.Save
    Case 5
        ShortcutLocation = cstr(rArgs(0))
        ShortcutPath     = objShell.SpecialFolders(ShortcutLocation)
        ShortcutName     = rArgs(1)
        Set objShortCut  = objShell.CreateShortcut(ShortcutPath & "\" & ShortcutName & ".lnk")
        TargetPath   = cstr(rArgs(2))
        objShortCut.TargetPath = chr(34) & TargetPath & chr(34)
        Arguments = cstr(rArgs(3))
        objShortCut.Arguments = Arguments
        IconLocation = cstr(rArgs(4))
        ObjShortCut.IconLocation = IconLocation
        Description = cstr(rArgs(5))
        ObjShortCut.Description = Description
        objShortCut.Save
    Case 6
        ShortcutLocation = cstr(rArgs(0))
        ShortcutPath     = objShell.SpecialFolders(ShortcutLocation)
        ShortcutName     = rArgs(1)
        Set objShortCut  = objShell.CreateShortcut(ShortcutPath & "\" & ShortcutName & ".lnk")
        TargetPath   = cstr(rArgs(2))
        objShortCut.TargetPath = chr(34) & TargetPath & chr(34)
        Arguments = cstr(rArgs(3))
        objShortCut.Arguments = Arguments
        IconLocation = cstr(rArgs(4))
        ObjShortCut.IconLocation = IconLocation
        Description = cstr(rArgs(5))
        ObjShortCut.Description = Description
        HotKey = cstr(rArgs(6))
        ObjShortCut.HotKey = HotKey
        objShortCut.Save
    End Select
End Sub
'-------------------------------------------------------------------------------------------------------
Hackoo
  • 1,410