In Windows 7, how to change proxy settings from command line?

Question

How do I change proxy settings from command line in Windows 7?

I'm not talking about just the http_proxy. I need to set system-wide proxy settings (the ones in Internet properties setting). How do I do that?

Answer 1

Simple and working solution retrieved from http://www.ehow.com/how_6887864_do-proxy-settings-command-prompt_.html

Command to enable proxy usage:

reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" ^
    /v ProxyEnable /t REG_DWORD /d 1 /f

Command to disable proxy usage:

reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" ^
    /v ProxyEnable /t REG_DWORD /d 0 /f

Command to change the proxy address:

reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" ^
    /v ProxyServer /t REG_SZ /d proxyserveraddress:proxyport /f

I have added line continuation (^) for improved readability. Also, in this case, it is more like a per-user setting than a system-wide setting.

Answer 2

NetSh to the rescue!

NetSh winhttp set proxy should be helpful. Here are the commands:

netsh winhttp set proxy myproxy

netsh winhttp set proxy myproxy:80 "<local>bar"

netsh winhttp set proxy proxy-server="http=myproxy;https=sproxy:88" bypass-list="*.contoso.com"

Answer 3

You'll need to configure a registry script that will make the changes you normally would via the Control Panel, and then merge the script to enable the proxy. You would also need an "undo" registry script to disable the changes.

In my case, I have two scripts, enable.reg and disable.reg:

Enable Proxy:

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings]
"AutoConfigURL"="http://10.10.10.1/autoproxy/proxy.pac"

[HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Connections]
"DefaultConnectionSettings"=hex:16,00,00,00,05,02,00,00,0d,00,00,00,0e,00,00,\
  00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00
"SavedLegacySettings"=hex:36,00,00,00,46,1a,00,00,0d,00,00,00,0e,00,00,00,32,\
  00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00

Disable Proxy:

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings]
"AutoConfigURL"=-

[HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Connections]
"DefaultConnectionSettings"=hex:16,00,00,00,05,02,00,00,0d,00,00,00,0e,00,00,\
  00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00
"SavedLegacySettings"=hex:36,00,00,00,46,1a,00,00,0d,00,00,00,0e,00,00,00,32,\
  00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00,00

In the "disable" script, the =- at the end of AutoConfigURL actually deletes the key from the registry.

Note that the values you see above are modified for the purposes of this answer. The actual hex values are much longer.

To use these scripts, I had a batch file for each one, looking something like this:

@echo off
start /min reg import C:\Path\To\Registry\File\enable_proxy.reg

That is fully workable from the command line.

Answer 4

I did it in C#, but the philosphy is the same, writing to the registry, so the following instructions can be extrapolated to line command. It shall be done three things:

1. Write to Registry "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings", on ProxyEnable: 1 to enable, 0 to disable

2. Write to Registry "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings", on ProxyServer: xxx.xxx.xxx.xxxx:yyyy (xxx... is the IP, yy.. is the port)

3. After performing steps 1 and 2 you will have written to registry the activation of proxy and the IP and port, but if you open the browser you will notice that it is not enough, you can't navigate yet. The third step consists of changing the registry regarding connections settings:

"Software\Microsoft\Windows\CurrentVersion\Internet Settings\Connections" on "DefaultConnectionSettings".

Notice that although (at least for W7) there are 204 bytes in this registry, you only have to modify byte 8 (9th since byte 0 is the first). Byte 8 value not only contains information about proxy enable/disable, but also about other functionalities:

        //09 when only 'Automatically detect settings' is enabled 
        //03 when only 'Use a proxy server for your LAN' is enabled
        //0B when both are enabled
        //05 when only 'Use automatic configuration script' is enabled
        //0D when 'Automatically detect settings' and 'Use automatic      configuration script' are enabled
        //07 when 'Use a proxy server for your LAN' and 'Use automatic configuration script' are enabled
        //0F when all the three are enabled. 
        //01 when none of them are enabled. 

In my case, the 'Automatically detect settings' is always enabled, so I switch the value of byte 8 from 09 to 0B and viceversa to enable and disable the proxy.

Answer 5

Create a batch file and paste following content(It will toggle the Proxy state),

@echo off

FOR /F "tokens=2* delims=    " %%A IN ('REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable') DO SET currentProxy=%%B
rem ECHO currentProxy=%currentProxy%

if %currentProxy%==0x1 (
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 0 /f
echo Proxy Disabled
) else (
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 1 /f
echo Proxy Enabled
  )

pause

Answer 6

This script may do it:

REM Enable-Disable System Proxy in one file
@echo off
SET home_key="HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"
FOR /F "tokens=3" %%L IN ('reg query %home_key% /v ProxyEnable' ) DO SET currentProxy=%%L
IF %currentProxy% == 0x1 goto turnoff
IF %currentProxy% == 0x0 goto turnon
:turnoff
reg add %home_key% /v ProxyEnable /t REG_DWORD /d 0 /f
SET proxy="Proxy disabled"
goto EOF
:turnon
reg add %home_key% /v ProxyEnable /t REG_DWORD /d 1 /f
SET proxy="Proxy enabled"
goto EOF
:EOF
REM Restart Internet Explorer to changes take efect
start /w /b iexplore.exe
timeout 2 /nobreak
taskkill /f /im iexplore.exe
echo %proxy%

Answer 7

I hope I am pointing you in the correct direction here, but if you are trying to access the proxy settings through "Internet options", simply open the start menu and type "internet option" (any setting or application you can locate this way also example "proxy"). You should then recognize this menu and be able to add your needed settings.