How do i get Magnet links with Deluge or is it even possible?

Question

They say it is not compatible any more? Why is the info hash button grayed out?

Does anybody know how do I get Magnet links with Deluge Web UI Client?

BTW, my Deluge Client Version is 1.3.5

Answer 1

I right click on the magnet link and "Copy link address" or similar, and then copy that link into deluge in the "add torrent".

Answer 2

For the Mac, GitHub user Lord-Kamina has written Deluge-Magnet-Handler, an AppleScript workaround. Installed in the Applications folder and run once to associate itself with magnet: links, those URL's should automatically open in Deluge thereafter.

on quit
    try
        tell application "System Events" to tell process "Deluge"
            activate
            set frontmost to true
            windows where title contains "Add Torrents"
            if result is not {} then perform action "AXRaise" of item 1 of result
        end tell
    end try
end quit

on open location this_URL
    try
        tell application "Finder" to set delugePath to POSIX path of (application file id "org.deluge" as string)
        set appExists to true
    on error
        set appExists to false
        display alert "Deluge.app must be installed in order to use this plug-in." as critical
        return
    end try
    set delugeArgument to quoted form of this_URL
    try
        tell application "Deluge" to activate
    end try
    do shell script (quoted form of (delugePath & "/Contents/MacOS/Deluge") & " add " & delugeArgument & "; return;")
    quit
end open location
tell application "Finder" to set thisPath to (POSIX path of (application file id "org.deluge.MagnetURIHandler" as string))
log thisPath
set lsToolRead to do shell script (quoted form of (thisPath & "/Contents/Resources/lstool") & " read url magnet")
if (lsToolRead contains "Magnet Handler.app") then
    display dialog "Magnet Handler is already the default application to handle magnet URIs" buttons {"OK"} with title "Notification" with icon POSIX file (thisPath & "/Contents/Resources/deluge_magnet.icns")
else
    try
        set dialogResult to display dialog "Magnet Handler has not been configured to handle magnet URIs.

Would you like to do this now?" buttons {"Yes", "No"} default button "Yes" cancel button "No" with title "Notification" with icon POSIX file (thisPath & "/Contents/Resources/deluge_magnet.icns")
    on error number -128
    end try
    try
        if button returned of dialogResult is "Yes" then
            do shell script (quoted form of (thisPath & "/Contents/Resources/lstool") & " write url magnet org.deluge.MagnetURIHandler")
            display dialog "Magnet Handler has now been configured as the default application to handle magnet URIs" buttons {"OK"} with title "Notification" with icon POSIX file (thisPath & "/Contents/Resources/deluge_magnet.icns")

        end if
    end try
end if
quit

Answer 3

According to AskUbuntu, magnet support in the WebUI was added in 1.3.4 back in May. Are you sure you're up-to-date?