3

I have this excel sheet where i want to protect some cells from formating and editing. All these cells are colored with a specific color.

The sheet is very big and therefor i am looking for a way to lock all these cells in a go and then be able to mass format all the other cells without changing the cells that i want to lock.

Is there some way to tell excel to lock cells with a specific color?

Behedwin
  • 65

4 Answers4

5

Yes, with VBa... Simply copy this into the "ThisWorkbook" in the Visual Basic Screen and then run it (green play triangle)

enter image description here

Sub WalkThePlank()

    dim colorIndex as Integer
    colorIndex = 3                   'UPDATE ME TO YOUR COLOUR OR BE FED TO THE SHARKS   

    Dim rng As Range

    For Each rng In ActiveSheet.UsedRange.Cells

        Dim color As Long
        color = rng.Interior.ColorIndex
        If (color = colorIndex) Then   
            rng.Locked = True
        else
            rng.Locked = false    'this will remove any locks for those not in the given color
        End If

    Next rng

End Sub

There is no undo in VBa, so take a copy of your file first (to create a back up)!

Colour index - http://dmcritchie.mvps.org/excel/colors.htm

How do I add VBA in MS Office?

The above assumes you have no merged cells and that your worksheet is not protected.

If you are not sure what the colorIndex you need is, then use this script first

Sub Find()

Dim colorIndexFinder As Integer
colorIndexFinder = Range("A1").Interior.colorIndex  'CHANGE A1 to the cell with the colour you want to use
MsgBox (colorIndexFinder)

End Sub

Edit

You have mentioned you do use merged cells

Please try

Sub WalkThePlank()

Dim colorIndex As Integer
colorIndex = 3                   'UPDATE ME TO YOUR COLOUR OR BE FED TO THE SHARKS

Dim rng As Range

For Each rng In ActiveSheet.UsedRange.Cells

    Dim color As Long
    color = rng.Interior.colorIndex

    If (color = colorIndex) Then
        If (rng.MergeCells) Then
            rng.MergeArea.Locked = True
        Else
            rng.Locked = True
        End If
    Else
        If (rng.MergeCells) Then
            rng.MergeArea.Locked = False
        Else
            rng.Locked = False
        End If
    End If

    Next rng

End Sub
Community
  • 1
Dave
  • 25,513
2

I have found this way by using a simple macro:

Select the whole sheet (Ctrl+A) and unlock all cells, and then use this macro to set the coloured ones to be locked again:

Dim c As Object 
For Each c In selection 
    If c.ColorIndex = 6 ' 6 is for Yellow - change to the colour you want
    c.Locked = True 
End If 
Next c
Leo Chapiro
  • 15,705
1

Vba solution (How do I add VBA in MS Office?)

Sub LockOnlyCellsWithCertainColor()
    'Change to your color
    Const colorToLock = 65535

    Dim currentCell As Range

    ActiveSheet.Cells.Locked = False

    For Each currentCell In ActiveSheet.UsedRange.Cells
        If currentCell.Interior.Color = colorToLock Then
            If currentCell.MergeCells Then
                currentCell.MergeArea.Locked = True
            Else
                currentCell.Locked = True
            End If
        End If
    Next

End Sub

Sub GetBackgroundColorOfActiveCell()
    Debug.Print ActiveCell.Interior.Color
    MsgBox ActiveCell.Interior.Color
End Sub
Community
  • 1
Siphor
  • 854
0

The below works for me as long as you unprotect the sheet first, color Index is set to 6 for yellow.

Sub Lock_by_Color()
Dim colorIndex As Integer
Dim Range As Range

colorIndex = 6
For Each Range In ActiveSheet.UsedRange.Cells
Dim color As Long
 color = Range.Interior.colorIndex
If (color = colorIndex) Then
 Range.Locked = True
Else
 Range.Locked = False
End If
Next Range

ActiveSheet.Protect , DrawingObjects:=True, Contents:=True, Scenarios:=True _
, AllowSorting:=True, AllowFiltering:=True, AllowUsingPivotTables:=True
ActiveSheet.EnableSelection = xlNoRestrictions
End Sub
Alex
  • 1